*save_checkpoint

*text_image chap_8.png center Chapter Eight
*temp aresinteraction 1
*temp staff false
*temp mamaoblivious false
*temp mamadismissed false
*temp mamamad false
*temp glare false
*temp confronthermes false
*temp caughtbyhermes false
*temp cameathim false
*temp foolish false
*temp noticedscar2 false
*temp distraction false
*temp heldhands false
*temp hermesthere false
*temp noticedscar1 false
*temp lockeduppoint false
*temp quietly false
*temp tbc false


*if morpheusoutcome = 4
    It is only when someone clears their throat–likely not for the first time, judging by the frustration tingeing the sound–that you remember yourself.

    You tear your lips away from Morpheus's. He blinks down at you, confused.

    It takes another, louder, cough for him to slide his fingers out of your hair and retrieve his hand from your lower back. 

    Their sudden absence almost hurts, but it's not like you can do anything about it.
    
    Not unless you want to further aggravate the lampad glaring at you from the mouth of the cave.
    *goto caveextra
*elseif morpheusoutcome > 4
    When Averna returns, she finds you curled up in Morpheus's arms, leisurely picking at @{(injured) the tray of food he brought earlier|a tray of ambrosia-laced fruit}.

    Mercifully, you're both dressed. More or less.

    Morpheus brought you @{(injured) another of his chitons|one of his chitons}, and the bed sheet he hastily wrapped around himself before he @{(injured) went to refill your mug of nectar|retrieved the food} covers him from the waist down.
    *goto caveextra
*else
    You're on your way back from Morpheus's, when you crash to a halt at the sight of it.
    *goto main51 

*label caveextra
*page_break

Averna gives @{(injured) Morpheus|you} a pointed look. "I distinctly remember telling you @{(injured) she|he} needed to rest."

"I did rest," @{(injured) you protest|he protests}.

Averna @{(justkissedmorpheus) glowers at the pair of you|takes in Morpheus's bare torso, the tender way he's cradling you to his chest, the hand he's softly resting on your hip}. "In that @{(injured) case|case and since he's clearly well enough}, I had better escort Morpheus to the King. He has requested you report to him at @{(argusspear) once|once|once|once|once. And that you bring Argus's spear|once. And that you bring Argus's spear|once}."

@{(justkissedmorpheus) Morpheus straightens|Morpheus's fingers tighten around your hip}.

"As for you," the lampad adds, shifting her focus to you, "you ought to return @{(injured) home, now that you've recovered enough|home}. @{(aresoutcome > 2) You have a visitor|The Queen awaits you}."

There goes your taste of sweet oblivion. Duty has caught up with you, and it's taking no prisoners.

*fake_choice
    #I must answer its call; there's too much at stake.
        *set leadership %+5
    #I must answer its call; it's only proper.
        *set dutiful %+5
    #What choice do I have, but to submit to its whims?
        *set dutiful %-5

@{(aresoutcome > 2) Then it dawns on you. A visitor?|Besides, your mother won't take too kindly to being made to wait}.

"Are you aware of what the words [i]at once[/i] mean?" Averna snaps at the pair of @{(aresoutcome > 2) you before you can enquire further|you}.

"I don't believe I'm familiar with the expression," Morpheus drawls, fixing his gaze on the platter of food and pondering its contents. He makes a big show of it too, picking up a few bits and setting them down with a shake of his head. When he finally settles on a ripe fig, he picks it up very slowly and takes a bite, smiling at the furious lampad before adding, "Please enlighten me."

The shadows around Averna flare as though poked by a stick.

"Alright, alright," you tell the lampad before turning to Morpheus. "You had better do as she says. This is her being nice."

For a second, you think he'll refuse. Then he @{(justkissedmorpheus) saunters over to the mouth of the cave|gets up. After a long, drawn-out stretch that makes Averna's shadows contort into angry whirlpools, he saunters over to the divider}.

@{(justkissedmorpheus) Averna's shadows contort into angry whirlpools.|Averna takes the opportunity to shoot you a look that screams, [i]Really?[/i] This [i]god?[/i]}

"Good boy," she @{(justkissedmorpheus) says|says when Morpheus returns, clad in a clean chiton}. It's the same voice she uses on Cerberus. "Now come. Hades is in Tartarus."

Your mother trained her well; her tone allows for no room to argue, no time to talk.

Morpheus glances at you. You get the distinct impression he'd much rather talk–or argue–with you than follow Averna into the sky.

But follow her into the sky he does. Grudgingly, scarred wing twisting at an angle, silver hair flowing behind him like a moonlit stream.

*page_break Hurry Home

Your journey back crashes to a halt, however, when you see it.

*label main51

Up ahead, blotting out far too much of the wood at the foot of the Erebus mountains, and a sizeable chunk of their slopes. The destruction Argus @{(argusencounter) wrought|wrought|wrought before he died|wrought}.

You had glimpsed it when you first saw Argus, and @{(argusencounter) when he had you pinned to that rock, draining the immortality out of you|when you chased him back to Tartarus|on the way back to Morpheus's place|when your parents had fought him, roots and shadows against flames and stone}.

But it's only now, without @{(argusencounter) the prospect of being cracked like an egg literally looming over you|the giant to wrangle|a god to save|a god to save}, that you truly grasp the level of sheer devastation. 

All that remains of this part of your realm is ash, debris and smoke.

*page_break

You can still taste it when you reach the acropolis, the discoveries of the last few hours weighing heavy on your mind.

A giant on the loose, a nymph turned mortal by breaking a Stygian oath, a herald @{(caughthermes) who is committing|accused of} treason.

You don't need to be one of the Fates to know these things could all be considered portents of doom. Though you suppose they could also offer the chance to

*fake_choice
    #Prove myself to the pantheon.
        *set dutiful %+5
    #Further my position in the pantheon.
        *set cunning %+5
    #Improve the current state of the pantheon.
        *set leadership %+5

A worthy pursuit, but one that will have to wait,
*if aresoutcome != 2
    *set aresishere true
    for Ares is in your chambers.
    *goto aresvisit
*else
    for the Queen is in your chambers.

    You recognize her straight-backed silhouette as you near the balcony and @{(parentsrel) pick up the pace|bite back a sigh|frown}.

    And she's seething.

    You can feel her rage even at this distance. Lurking beneath her perfect facade like a beast in the thicket.

    Hungry and ready to pounce.
    *goto queenishere

*label aresvisit

Or rather, keeping a respectful distance from–and his back promptly to–the colonnade that leads to them in what you're certain is his way of respecting your privacy.

His head jerks up at your approach. He straightens, nervously rubbing the back of his neck with his free hand. The other is holding onto his helmet. A ridiculous contraption, made of adamant to match the ridiculous suit of armor he's strapped into.

Upon landing, you

*fake_choice
    *if justfriendsares = false
        #Throw my arms around him; I've missed him.
            *set Ares %+10
            *set aresinteraction 1
            It catches him off guard, and almost knocks him off his feet. But he rights himself, laughing into your hair as his helmet clangs to the ground and he wraps his brawny arms around you.

            His breastplate smashes into your chest, but you don't care. You don't technically [i]need[/i] to breathe, and your ribcage will take a lot more than that to @{(injured) break. A fact you're too keenly aware of after Argus almost succeeded|break}.
    #Offer him my warmest smile; I've missed him.
        *set Ares %+5
        *set aresinteraction 2
        He returns it, dimpled cheeks turning pink.
    #Shoot him a worried look; he shouldn't be here.
        *set Ares %-5
        *set aresinteraction 3
        Yes, he told you he'd like to visit in his last scroll, but to just show up, and jeopardize his health this close to the feast, is a risky move. 
    #Demand to know what he's doing here.
        *set Ares %-10
        *set aresinteraction 4
        You cross your arms and eye him with a mixture of curiosity and suspicion.

        "What are you doing here?" Last you heard, he was meant to be at the bottom of the ocean.

"I'm sorry for intruding on you unannounced," he offers, @{(aresinteraction) hands still bracketing your waist|grin faltering slightly|smiling apologetically|avoiding your eye}. "I was on my way back from my uncle's and, well, I…I was already deep within the earth's bowels, so I thought, why not drop by, you know? Since I'm so close, and all."

*fake_choice
    #"So what you're saying is, you missed me."
        His reply comes quick and brimming with earnestness. "Yes."
    #"So you're just here because it was convenient?"
        Panic floods his face.

        "Yes." He flinches before adding, "Wait, no. It [i]was[/i] convenient. But also, and mostly, I'm here because I wanted to see you."
    #"So you're not here to declare war?"
        He looks horrified. "Of course not."

@{(aresinteraction > 2) "I see. Have|"I'm glad to hear it. Have} you been waiting long?"

He shakes his head. "I came through the main gates and was greeted by, eh, a very efficient nymph who escorted me here and told me not to move if I knew what was good for me." 

You wave him off. "That would be Averna. Don't take it personally, she's mean to everyone."

"That's reassuring. I thought perhaps I had broken some sort of rule by giving Cerberus snacks. In fact, when I heard you approach, I feared you might be a Fury come to deliver my punishment."

"Cerberus let you feed him?" you gasp.

The hound has bitten deities' hands off for less. They grow back, of course, but it's still a gnarly sight.

"Why wouldn't he?" He frowns, as though he genuinely can't fathom the Underworld's fiercest sentinel refusing snacks from visitors. "Though that does remind me, I'm all out of ambrosia cake. Sorry."

Ah. That explains it. A bone would've gotten Ares nowhere. A syrupy bake, however, is the kind of bribe Cerberus can't resist. "He has a sweet tooth, that one."

Ares's dimpled grin widens. "Several of them."

*page_break True

Ares's gaze
*if (injured = false) or (scar = 3)
    fixes on the smoke-filled sky in the distance.

    "Is it always so…ominous?" he asks. "The nymph–Averna–was also adamant I mind my own business, yet I can't help but be curious. And slightly concerned."
    *goto aresvisit1 
*else
    *set noticedscar true
    travels down your neck, and widens when he notices the scar @{(scar) twisting down your shoulder|etched across it|na}.

    "${name}. Are you alright? What happened?"
    *goto aresvisit1

*label aresvisit1

You weigh your answer. You might want to hold off on discussing Argus's escape attempt with Ares–or anyone else, for that matter–until you speak with your parents.

They'll want to control how Olympus comes by this information, and how much of it they obtain. Then again, you doubt Ares will tell them. 

[i]We only talk about marriage or war. Or rather,[/i] they [i]only talk about marriage or war. I am usually thinking about what Maia might have left for me in the kitchens,[/i] he'd written in one of his scrolls.

*fake_choice
    #@{(noticedscar) "A Giant happened,"|"It's only this ominous after a Giant attack,"} I offer.
        *set dutiful %-5
        *set parents %-5
        *set toldares true
        His expression is worthy of immortalizing on a vase.

        Disbelief, horror and anguish fight for control of his face as you reveal what happened. When you're done, he @{(aresinteraction > 1) stares at you for so long and in such stunned silence, you wonder whether he's forgotten how to speak|pulls you closer anew, embracing you for so long, you wonder whether perhaps your ribs might give under his breastplate after all}.

        @{(argusencounter) "Does it hurt?" he breathes|"You wrestled a giant," he says, and the awe in his voice makes you smile|"I didn't know that's what breaking an oath did," he breathes|"I'm glad your parents were there," he breathes}.

        @{(argusencounter) "Not anymore."|"What, like it's hard?"|"Nor did I," you admit.|"As am I," you agree}.
    #@{(noticedscar) "You should see the other guy,"|"She's a piece of work, isn't she?"} I deflect.
        *set parents %+10
        It doesn't fool him. @{(noticedscar) In fact, it appears to pain him. But|But} he doesn't push you.
        
        He's ever so respectful.

        @{(noticedscar) "I don't doubt you handled him deftly,"|"Sure is,"} he says with a small, brittle smile.
    #@{(noticedscar) "I'm not at liberty to say,"|"It's not always this ominous, no,"} I admit.
        *set diplomacy %+5
        @{(noticedscar) Anguish plagues his face|His brow knits together}. "That's all I get?"

        "Afraid so."

Before he gets the chance to say anything else, however, he stumbles. @{(aresinteraction > 1) His helmet clatters to the ground, and he might have followed had he not held onto the banister|He lets go of you, and might have hit the ground if you didn't catch hold of him}.

"Perhaps I may have been waiting for longer than I realized," he confesses, struggling to remain upright.

A loud rapping on your door makes you jump, and him swerve.

*fake_choice
    #"Help!" I plead.
        *set staff true
        Your mother storms into the room and onto the balcony, staff in hand, murder in her eyes.
    #"Come in!" I shout.
        Your mother marches into the room and onto the balcony.
    #"Go away!" I warn.
        It doesn't stop your mother from marching into the room and onto the balcony.

She takes a single look at Ares and snaps into action, @{(aresinteraction > 1) grabbing one of his arms and gesturing for you to do the same with the other|helping you hold him up by slinging one of his arms around her shoulders}. 

"Silly god. What were you thinking?" she chastises him under her breath.

"I was thinking it would be nice to hear ${name}'s voice again, not just in my head like I do when I read her scrolls. In the real. In reality. No, in person."

So this is what happens to Olympians who spend too long in the Underworld without eating from its orchards. They become like drunk mortals. Loose-lipped and witless.

"Averna!"

No sooner has your mother called for the lampad that she appears, sliding out of the shadow of one of the columns. "Yes, Mistress?"

"There she is!" Ares practically yells with a start, almost toppling both you and your mother over in the process. "The scary nymph. Are you here to be mean to me again?"

Averna's lips quirk upwards as she turns to your mother. "Am I?"

"Help us get him to the Dream Gate, will you? If he doesn't leave this realm soon, he'll be as good as dead."

*page_break Drag Ares To The Gate

It takes much effort, some gentle coaxing on your part and a lot of berating on Averna's to get him there, but you eventually do. Thank the Fates.

"Who built your armor, big guy?" Averna huffs after you've leaned Ares against one of the pillars so that you might recover your dignity, if not your breaths. "I'd like to burn their workshop to the ground."

"Si…six…sy…." Whatever he's trying to say evades him, as does his balance. His back slides down the column, and as his rear hits the grass with a loud thud, he exclaims, "Syxclops! A syxclops."

Your mother, who had the foresight to pick up his helmet, hands it to the nymph. "Will you ensure he gets home safe? I must speak with my daughter." She shoots you a warning look, shutting down any protests before they get the chance to arise. "Trust me, it is for the best."

Averna nods, grabbing the helmet with a sigh. "C'mon big guy," she tells Ares, "let's get you some fresh air."

"Oooh, pretty flowers," he coos, reaching for one of the @{(flower) crocuses|daffodils|quince flowers|nightshades} draped around your side. He sniffs the bloom and smiles. "They smell pretty too. Just like ${name}."

He waves at you, and might've even attempted a return to your side, if Averna hadn't shoved him through the gate.

"Gods," she sighs before following after him.

*label queenishere
*page_break

As soon as @{(aresishere) you're alone, the Queen's|your sandals brush tile, she's} by your side, pulling you into her arms and hugging you so tight it almost hurts. 

When she finally relents, she keeps her hands on your shoulders and
*if injured
    chokes out, "Show me."

    Her gaze flickers to your @{(scar) shoulder|neck|leg}. You @{(scar) twist your arm|bare your throat to her|lift Morpheus's chiton} and show her your scar.

    The Queen's face darkens at the sight of it. @{(aresishere) Rage lurks beneath the surface of her face like a beast in the thicket, hungry and ready to pounce|Her rage returns, wild and sharp}.
    *goto premain52
*elseif gothelp
    asks, "How is Morpheus?"
    *goto notinjured
*else
    chokes out, "Thank the Fates you're alright."

    She still looks you up and down several times, just to make sure. Only after she's satisfied does she ask, "How's Morpheus?"
    *goto notinjured

*label notinjured

Thinking of his ichor-drenched wing makes you wince. "Recovered. Averna made sure of it. He'll have a nasty scar though."

*label premain52

She nods, 
*if aresishere
    then glances at the gate. "You don't need to worry about Ares. He'll be alright," she says softly. "I would advise you meet elsewhere in the future, however. If he remains here too long, it might take him longer to recover. We need him at his best for the feast."

    *fake_choice
        #"And here I thought you'd gone soft on me."
        #"And here I thought you were done reprimanding me."
        #"And here I thought you were being kind."

    Her palm grazes your cheek. "Never."
    
    Then her face darkens.
    *goto main52
*else
    then her face darkens.
    *goto main52

*label main52

@{(argusencounter) "Argus has been…reluctant to talk thus far." She lifts her chin, barely containing her fury. Despite the mark he left on you, you almost feel bad for the giant. "Do you know who freed him?"|"Do you know who freed Argus?"|"What happened?"|"Do you know who freed Argus?"}

*if argusencounter = 3
    "Argus broke a Stygian oath on purpose. So that he may become mortal. So that he may [i]die.[/i]"

    Your thoughts flicker back to Pasithea, to the vase depicting Morpheus at her death bed, to the injustice of having to watch a loved one die when they could've lived on forever.

    "That explains why his trail vanished," your mother mutters to herself. Then she holds your gaze anew. "Do you know who freed him?"
    *goto main53
*else
    *goto main53

*label main53

What do you tell her?

*choice
    #The truth. I wouldn't dare lie to my mother, let alone my Queen.
        @{(argusencounter) "Morpheus thinks it was Hermes."|"Morpheus thinks it was Hermes."|"It was Hermes."|"Morpheus thinks it was Hermes."}

        *if dutiful > 55
            *set parents %+10
            *set underworldinfluence %+10
            *set toldmama 1
            *goto wellreceived
        *else
            *set parents %-5
            *set underworldinfluence %-5
            *set toldmama 2
            *goto reluctant
    #The truth. I wouldn't dare jeopardize the realms any further.
        @{(argusencounter) "Morpheus thinks it was Hermes."|"Morpheus thinks it was Hermes."|"It was Hermes."|"Morpheus thinks it was Hermes."}

        *if leadership  > 55
            *set parents %+10
            *set pantheonplayer %+10
            *set toldmama 1
            *goto wellreceived
        *else
            *set parents %-5
            *set pantheonplayer %-5
            *set toldmama 2
            *set mamadismissed true
            *if argusencounter = 3
                *goto reluctant
            *else
                "I didn't ask you what Morpheus thinks." Her voice is hard, her grip on your shoulders firm. "I asked you what [i]you[/i] know."

                You feel yourself shrink under the weight of her scrutiny, the depth of her disappointment.

                No matter how hard you try, in her eyes, you'll never be queenly enough.
                *goto extrahermes
    #I lie. I would rather handle Hermes myself.
        You shake your head. 
        
        "Not yet."

        Your gaze doesn't stray from hers, and your voice doesn't waver.
        *if cunning > 60
            *set maverickgoddess %+15
            *set parents %-5
            *set mamaoblivious true
            *set toldmama 3
            It's a convincing enough performance, for she doesn't question it.
            *goto premission
        *else
            *set underworldinfluence %-10
            *set parents %-15
            *set mamamad true
            *set toldmama 4
            It's a convincing enough performance. Someone else might've fallen for it.

            But not your mother.
            *goto premission

*label wellreceived

She stills, letting the information sink in.

But she doesn't question it, nor your judgement.

"That is troubling to hear," she sighs, squeezing your shoulders.
*goto extrahermes

*label reluctant

A frown ghosts over her brow. 

"You are certain?"

You nod, but her doubt stings. You may not @{(mamadismissed) possess her ability to command a room, and inspire loyalty–or fear–in others|always do as your told}, but you're her daughter.
Rather than exploit the information, you chose to trust her with it. The least she could do is trust you back.

Her next words sink into you teeth first, proving the extent of her faith in you.

"Your father will crosscheck with Morpheus."

*label extrahermes

"Hermes has been targeting cities without patron deities and skimming worship meant for Hypnos," you explain.

*label premission

@{(toldmama) Worry ghosts across her face. You place a tentative hand over her fingers, hoping it will comfort her.|Despite your best efforts to sound assertive, your voice comes out small and forlorn|"That is unfortunate. Let us hope your father will get something useful out of Morpheus."|"This is not the time for secrets," she snaps, sharp enough to make you wince.}

@{(toldmama) Instead, it rallies her|Either she doesn't notice, or she doesn't care. You can't blame her; there are far more pressing concerns at hand than your bruised feelings|Worry ghosts across her face, but you don't let it, nor her next words, guilt you|"I–" you begin, but she cuts you off}.
            
"Our realm has just suffered a massive security breach and half of it is in shambles. Our standing with Olympus, our reputation among the Giants, the very safety of every mortal in Hellas, depends on what we do next, 
*if toldmama = 4
    so you had better start talking, daughter, before I make you."

    Her rage sinks its talons into you, clawing out the truth.

    @{(argusencounter) "Morpheus thinks it was Hermes.|"Morpheus thinks it was Hermes.|"It was Hermes.|"Morpheus thinks it was Hermes.} He has been targeting cities without patron deities and skimming worship meant for Hypnos."

    It's hard to know if the anger pulsing through her is directed at the herald, or at you for attempting to keep his involvement from her.
    
    "How am I supposed to trust you with what comes next?" she wonders.
    *goto main55
*else
    so we must ensure it's the right thing."
    *goto main54

*label main54

She pauses and gives you a
*if (toldmama = 1) or (toldmama = 3)
    solemn look. "I need your help to make it so."
    *goto main55
*else
    hard look. "I don't know if you're ready to help me make it so."
    *goto main55

*label main55
*page_break

You @{(toldmama) nod and wait for her to continue|say nothing. Your words clearly don't mean much to her|nod and wait for her to continue|nothing, well aware that your word means nothing to her now}.

"Zeus has requested we meet him tomorrow. He wants to establish a feast planning committee. We will arrive early and discuss Argus's escape with
*if mamaoblivious = false
    Zeus then." She pauses, watching you carefully. 
    *if toldmama = 1
        "You showed great @{(argusencounter) resilience. Scar or no, not|strength containing Argus. Not|resilience with Argus.|judgement, managing to evade Argus and seek hep. Not} many young deities have faced a Giant and lived to tell the tale. Which is why I'm asking you to keep an eye on Hermes. And to speak to no one else about this. If he gets wind we're onto him, who knows how far he'll go to save his own skin."

        *if toldares
            *goto aresconvo
        *else
            *fake_choice
                #"He's gone too far already," I sigh.
                    Your mother nods. "Indeed."
                #"I won't let you down," I promise.
                    *set parents %+10
                    "I know."
                #"You're asking, or ordering?" I enquire.
                    *set parents %-5
                    Her lips press into a thin line. 

                    "Whichever one gets you to do it," she grits out.       
            *goto spearconvo
    *else
        @{(mamamad) "You better not speak of what happened here to anyone until then. Understood?"|"Can I trust you to speak nothing of what happened here until then?"}

        *if toldares
            *goto aresconvo 
        *else
            @{(mamamad) You nod, thoroughly chastised|"Of course." She could trust you to do more than that, too}.
        *goto spearconvo
*else
    Zeus then. Until we know who let Argus loose and why, we can't trust anyone, and we certainly can't share what happened here."

    You can't promise @{(toldares) anything. Mainly because it would already be an empty promise. But|anything, but} you know better than to tell her that.
    
    "Understood," you say instead.
    *goto spearconvo

*label aresconvo

You wince. "About that." 

She narrows her eyes at you, but you force the words out anyway. "I may have told Ares about Argus. Just a little bit."

"Define a little bit," she grits out.

"@{(argusencounter) Mostly how badly he battered me|Mostly how heroically I acted|Mostly how shocking it was to witness him perish before my very eyes|Mostly how heroically you and Father behaved}."

She pinches the bridge of her nose, muttering under her breath before she regards you anew. "Did you share your suspicions about Hermes?"

You shake your head. "He went all loopy before we could get to that part."

"Good. Let us hope he has more sense than you and keeps his mouth shut."

*label spearconvo
*page_break

"Averna tells me
*if argusspear < 5
    you took Argus's spear, yes?" the Queen asks.

    "I did."
    *goto handoverspear
*else
    Morpheus took his spear, yes?"

    "He did."
    *goto handoverspear

*label handoverspear

You summon the weapon. It floats between you, tall enough and wide enough it might be mistaken for a column.

A column of fire.

The flames licking at the blade are less hungry than they were when Argus wielded it, but their heat still engulfs @{(aresishere) the clearing, drenching it|your chambers, drenching them} in blazing amber, and making your gown stick to your skin.

*label handoverspear1

"Good. For now, it's our only proof that Argus was broken out of Tartarus, rather than 
*if toldmama = 3
    escaped. Though whoever stole it covered their tracks well."
    *goto premain56
*else
    escaped. Though Hermes covered his tracks well. There is nothing or no one linking him to the scene.
    *goto premain56
*label premain56
Which is why it must be returned to the armory. A prison break looks bad, a prison break [i]and[/i] a break-in? It is the kind of incompetence that could cost us our ambrosia shipments for the next century or two."

*if argusspear < 5
    *if argusspear = 1
        You cross your arms. "I believe I earned the right to wield it."

        "That may be true," she concedes. "And you have my word you will, once we deal with this setback."
        *goto main56
    *else
        "It's all yours," you tell her, glad to see the back of it.
        *goto main56
*else
    *goto main56

*label main56
*page_break

Then she waves her hand anew, causing a scroll to appear in it. "I took the liberty of acquiring your instructions for tonight from Iris, lest they get too close to the wood. Though it's unlikely, given how busy they are helping Hermes guide souls to the main gates." Her face grows somber, her voice hard. "Kallisti has been hit by a deadly disease. Many mortals have perished in its wake."

Kallisti. You've heard of it. An island on Hellas's east coast. Its patron god, Euphemus, is a son of Poseidon. You know, because Averna went out with him once and complained incessantly about it afterwards. Apparently, he insisted on proving he could dance on water, not just walk on it.  Her reenacting of the ordeal had been enough to set your teeth on edge.

"Euphemus or the Fates?" you ask. Given Averna's impression of the sea god, you wouldn't be surprised if he was one of those patrons who resort to extreme measures when they feel they haven't been worshipped well enough by their followers.

"Both. It seems the disease arose without his knowledge, but he's done little to quell it."

*fake_choice
    #"He ought to be stripped of his patron privileges, then."
        *set leadership %+5   
    #"He ought to be punished for being such an incompetent patron, then."
        *set charm %-5
    #"He ought to be offered aid to protect his people, then."
        *set ruthless %-5

"Perhaps, but Olympus is diverting all resources to preparing for the feast now that Zeus has chosen where to hold it," your mother offers. "I believe it's an island called Leukas."

You freeze. Did you hear that right?

*page_break Did She Say Leukas?

At your expression, your mother frowns.

"Oh. I was under the impression you were familiar with the place."

"I am, but I wasn't aware Zeus was that fond of it," you say, taking Hermes's scroll from her.

The news

*fake_choice
    *if theronoutcome = 2
        #Horrifies me. Leukas is hardly worthy of such an honor.
            *set Theron %-5
            *set ruthless %+5
            It's a nice enough island, with nice enough people. But surely such an important event deserves more than 'nice enough'?

            As though she can read your mind, your mother's frown deepens.
    #Enrages me. The Leukans have been through enough.
        *set dutiful %-5
        *set charm %-5
        First, the nightmares. Then, the heroes. Now, this? If things go south–and chances are they will–the island will be destroyed, along with its people.

        "Why?" you demand, causing your mother's frown to deepen.
    *if theronoutcome != 2
        #Horrifies me. I don't want Theron to get hurt.
            *set Theron %+10
            @{(injured) The thought alone makes your scar burn|You think of Morpheus's scarred and twisted wing}. If a deity can barely survive a Giant's weapon, what chances does a mortal have?

            "Why?" you rasp.

            Your mother's frown deepens.
    #Gets me thinking. Is Leukas truly the best tactical choice?
        *set cunning %+5
        The Queen seems to read your mind, because she promptly offers an explanation.

"It is far enough from the Giants' territory to force them to expend some resources getting there, but close enough that they cannot complain about it," she explains. "It also lacks a patron deity, and all the political maneuvering dealing with one would require. Plus, I believe, it was recently host to a crew of heroes who have been singing its praises since they set sail from its shores."

Of course they have. "Has the Lord of Leukas been informed?"

"Not yet, but I believe Zeus is planning to deliver the news tomorrow at sunset, provided our meeting doesn't run over. Until then, carry on with your duties as usual @{(toldmama > 1) and please, for the love of the Fates, try to keep a low profile."|and stay safe. I'm asking you to watch Hermes, not to put yourself in harm's way. Understood?"}

@{(toldmama) You nod. "Got it."|You bristle at her tone. "Sure."|That, you can't promise either. And yet. "Got it."|You will make no such promises, no matter how hard she glares at you as a result.}

*if noextravases
    *goto beforeleaving
*else
    @{(toldmama < 4) She gives|Still, she can't seem to help giving} you another once over, as though to reassure herself you are, in fact, whole. Your mind flickers back to the vases. To the one where Pasithea's divine form shatters, leaving a frail mortal in place of the powerful nymph.

    Now would be a good time to bring it up. To understand if your parents knew. If they stood by while it happened. If they @{(morpheusmother) even cared|even cared|even cared|even cared|might even forgive you, if you broke an oath yourself|even cared|even cared}.

    *choice
        #So I do, gently. "Did you know about what Hypnos did to Pasithea?"
            *set parents %+5
            Surprise strikes her face. Whether at the mention of the nymph, or at the fact you know what happened to her, you can't tell.

            "I did," she says softly.
            *goto pasitheaconvo
        *if morpheusmother != 5
            #So I do, angrily. "How could you let Hypnos get away with what happened to Pasithea?"
                *set parents %-10
                *set glare true
                "Check your tone, daughter," she snaps, her voice chilled by cold rage. "And your presumptions."

                @{(parentsrel) You lower your chin, chastised|You lift your chin, unfazed. Her anger may be fierce, but you're too well-acquainted with it to care|You hold her gaze, refusing to back down but saying nothing}.
                *goto pasitheaconvo
        *if morpheusmother = 5
            #So I do, tentatively. "How do you feel about what happened to Pasithea?"
                *set Theron %+5
                *set suspects true
                Surprise takes over her face first, but it's quickly replaced by suspicion.

                "Why would it matter, what [i]I[/i] feel about what happened to Pasithea?"

                "I would like to know," you answer simply.
                *goto pasitheaconvo
        #But I don't. @{(parentsrel) I|Despite everything, I|I} know my parents are good deities.
            *set parents %+10
            What happened to Pasithea was terrible. If they could've stopped it they would've. 
            
            You don't need to hear your mother say it to know it.
            *goto beforeleaving

*label pasitheaconvo

"Pasithea and I were never close, so there was no reason for me to assume she wasn't aware of Hypnos's preferences," she explains after a long sigh. "For me to assume she wasn't happy, as many are, with an arrangement in which love didn't hinge on exclusivity. In fact, I thought that was what drew Pasithea to Hypnos in the first place. By the time I realized how wrong I was and tried to warn her, it was too late. She was certain he loved her the same way she loved him."

She grows quiet for a moment, lifting her hand to a couple of nearby souls. They weave between her fingers, casting a silver glow onto her face before she adds, "The worst part is, when I saw them together, I was almost certain too. He seemed completely enraptured by her."

[i]My father does a very convincing impression of an attentive god[/i], Morpheus had told you. It appears your mother would agree.

"I don't believe neither your father nor I could've predicted how tragically their story would end," your mother @{(suspects) continues. Then she eyes you with a strange expression, studying your face as though she can glimpse what truly lies behind your curiosity|continues}. "Her mortal life was one of sorrow and suffering, and it pains me that Morpheus had to witness @{(suspects) it. But, I suppose, it didn't have to be. Mortals may not live long, but that doesn't mean they can't live well, Fates willing|it}. Does that answer your question?"

You suppose so.

*label beforeleaving
*page_break

You expect her to leave. After all, she has a realm to rebuild and a prison to secure.

But she doesn't. Instead, her expression shifts.
*if morpheusoutcome > 4
    She studies Morpheus's chiton, hanging off you like a too-big cloak, before pinning you with a serious stare.
    *goto main57
*else
    Softens.
    *goto main57

*label main57
*page_break

"If the Underworld and Olympus's alliance is to be consolidated with a marriage, Zeus will want to announce it at the feast," she cautions. "Your father was chosen for me, and though it worked out for us in the end, it often does not turn out that way." 

Her words make you think of Aphrodite, a goddess of love who does not love her husband, and of Hera, a goddess of marriage whose husband does not love her.

"The Fates blessed your father and I, [i]eventually[/i]. If my worship were worth anything to them, I would offer all of it so that they may bless you and whomever you choose to give your heart to as well. Alas, they do not concern themselves with such trivial things."

@{(aresishere) A path of roots forms beneath her feet, lifting her towards the treeline|She makes for the door, pausing before she opens it}. "Contrary to what you might think, I do not expect you to marry Ares, or anyone you do not wish to. But I do expect you to have made a decision on the matter before the feast. It's a whole moon cycle away. I'm aware it may not seem like a lot of time, but it's more than most of us ever get."

With that, she leaves you to your racing thoughts.

*page_break 

Her words seem to linger in her absence.

Like the Queen herself, they are powerful and purposeful.

And they're all you can think of until you unroll Hermes's scroll, and frown at the single line jotted down on it.

[i]Your services are not required this evening.[/i]

Odd, and extremely suspicious. Or perhaps extremely auspicious. 

A free schedule is just what you need to deal with Hermes and

*fake_choice
    #@{(toldmama) Make my mother proud and prove I'm worthy of the trust she placed in me|Prove my mother wrong; I'm capable of this and more|Make lying to my mother worth it; I don't feel particularly proud of that|Prove my mother wrong; I'm capable of this and more}.
        *set parents %+10
    #Satisfy my curiosity; I want to know what he's up to and why.
        *set cunning %+5
    #Keep the realms safe; I must stop him once and for all.
        *set leadership %+5
    *if injured
        #Hold him accountable for what he did to me.
            *set ruthless %+5
            *set revenge true
            *set revengereason 1
    *if (injured = false) and (morpheusoutcome > 1)
        #Hold him accountable for what he did to Morpheus.
            *set Morpheus %+10
            *set revenge true
            *set revengereason 2
    *if theronoutcome != 2
        #Hold him accountable for what he's done to the Leukans.
            *set Theron %+10
            *set revenge true
            *set revengereason 3

*if theronoutcome != 2
    *set theronreason 1
    Still, you can't help but think of Theron. Hellas being the host of a feast that could lead to a war with the Giants is the kind of news Zeus will present as an honor.

    But you know the Lord well enough to know he won't agree.

    Once you're done with Hermes, you'll check in on him. Warn him about the danger hurtling his way, even if there isn't much he can do to stop it.
    *goto main58
*else
    Determined to make it so, you toss the scroll away.
    *goto main58

*label main58
*page_break Fly to Kallisti

The sun is high in the sky, bathing Hellas in warm, golden light.

You haven't visited the mortal realm at this hour in, well, an eternity. The brightness is far from the relentless splendor of Olympus, but it bewilders you nonetheless, and reminds you of spring's impending approach.

Kallisti is hard to miss. A faded rainbow points to the island like an arrow, leading you to the main city, which is shrouded in tendrils of smoke. As you near them, you catch their scent; myrtle, mint and flesh.

Funeral pyres.

*page_break Follow The Rainbow

Kallisti's cobbled streets are haunted by ghosts. Their spectral forms hover in the shadows, watching their bodies turn to ash and their loved ones mourn. You land where the rainbow ends, near the edge of the village, at the foot of one of its rocky hills. 

Iris isn't here, but you hear their voice drifting from an alleyway nearby. 

"…got the impression there was more to it," they're saying.

"I doubt it's anything to worry about. You know how gloomy Chthonic deities can be. They love to be all brooding and mysterious," Hermes offers in return.

"I didn't mean to imply they were hiding something. I only worry that they require help with whatever is clearly troubling them."

You realize they're talking about the Underworld. About your parents.

"I wasn't able to speak to ${name} or Morpheus," Iris adds, their concern obvious. "Persephone seemed particularly upset when I mentioned Morpheus's name. I fear something might have happened to him. Something terrible."

*page_break Silence

"I'm sure it's nothing," Hermes dismisses them after a beat. There's an edge to his voice that wasn't there before. "Why don't you take the next batch. It'll give you a chance to check up on them again. Besides, I'm bored of all this moping. I must return to Olympus and store some scrolls in the Archives."

"I can go. I haven't been in a while. It would be nice to catch up with Clio and I have some deliv–"

"No," Hermes cuts them off. "You will ensure these souls are taken to the Underworld like I asked you to do. Understood?"

You're about to round the corner where you expect to find them, when
*if morpheusoutcome > 2
    *set morpheuswith true
    a beringed hand closes over your mouth.
    *goto morpheusscene
*else
    *set morpheusalong 1
    you pause.

    What's your game plan?
    *goto main59

*label morpheusscene 
*page_break What in Tartarus?

@{(flightstyle) Your wings press|Your back presses|Your back presses} into what feels like marble, but you belatedly realize is someone's chest as strong arms haul you into an empty home.

"Don't scream," Morpheus whispers in your ear. Then, after a slight pause, he adds, "Please."

*fake_choice
    #I bite down on his hand. Hard.
        *set charm %-5
        "Ouch," he groans, letting go of you.
    #I nod and lift my hands up.
        *set diplomacy %+5
        *set quietly true
        Slowly, deliberately, he lets go of you.
    #I twist out of his grip.
        *set fitness %+5
        @{(fitness > 55) Easily done. The only reason he got the jump on you in the first place was because he caught you by surprise|Or perhaps he lets you go. Who's to say.}

Free of his grasp, you wheel around and @{(quietly) whisper, very sharply,|practically shout,} "What is wrong with you?"

Panic glints in his violet eyes. "Keep your voice down."

@{(quietly) You [i]were[/i] keeping your voice down. Perhaps that's why you|You} lift your chin, glaring at him as you hurl out, "Make me."

His eyes dart to your lips and you realize too late how such a challenge might be interpreted.

*fake_choice
    #I double down and take a step towards him.
        *set Morpheus %+10
        "Well?"

        He licks his lips. Is he thinking of pressing them to yours? Of @{(morpheus > 3) how good it had felt the last time he did?|how close you had come to it, in his chambers?}

        The sudden sound of footsteps puts a stop to such extremely unhelpful thoughts. You both eyes snap to the window, but it's only a mourner, hurrying along to join the others.

        Relief eases the sharpness in Morpheus's shoulders.
    #I pretend I don't notice and glare at him harder.
        *set Morpheus %+5
    #I save face by changing the subject.
        *set diplomacy %+5
        "What's this all about, anyway?"

Now that the shock of being dragged here has worn off, you notice how out of sorts he looks. @{(injured) There's|It isn't just his injured wing. There's} a hollowness to his pretty face, an ashen hew to his silver hair. Your father must've really laid into him, then.

"I'm merely trying to stop you from doing something foolish," he offers.

*fake_choice
    #"Says the most foolish deity I know."
        "Interesting," he says, his voice low, his eyes glinting. "I don't recall you calling me foolish earlier."

        "No, but I did call you vile, and I stand by it."
    #"How outrageously altruistic of you."
        "You're welcome," he says, voice low, eyes glinting.

        "And you're vile."
    #"So I should be grateful to you?"
        "It would certainly be appropriate."

        "The likelihood of that happening is about as high as one of us dying of natural causes."

A grin cracks his cheeks, chasing away some of that listlessness.

There's a strange comfort in sparring with him, even if the time and place is hardly comforting. In knowing that this, at least, remains the same.

Because everything else between you has changed. You can feel it in the current of uncertainty behind his eyes when they find yours, in the memory
*if morpheusoutcome = 3
    of how forlorn he'd looked in his chambers, when you thought you might kiss.
    *goto morpheusscene1
*else
    of his mouth on your neck, shoving its way to the forefront of your mind.

    [i]Tell me you want me to stop, then. Tell me you don't want this, don't want me the same way I want you.[/i]

    Though perhaps things between you haven't changed. Perhaps they've always been this way, and what's different is that you can't pretend otherwise.

    *fake_choice
        #It's true. Everything has changed. I feel drawn to him like never before.
            *set Morpheus %+10
            Fates help you.
        #It's true. Nothing has changed. I was just fooling myself before.
            *set Morpheus %+15
            Yes, you hated him. Part of you hates him still. But you've always been drawn to him, deep down.
        #No. @{(justkissedmorpheus) Kissing|Laying with} him was just a heat of the moment thing.
            *set Morpheus %-10
            *set unsureaboutmorpheus true
            You can't be sure just yet.
    
    *goto morpheusscene1

*label morpheusscene1

"Am I wrong, then? Were you not about to do something foolish?" he asks, raising a very judgemental eyebrow at you.

"Obviously not," you snap. You didn't get the chance to do anything, foolish or otherwise.

*label main59
*page_break

Your mother asked you to keep @{(toldmama) an eye on Hermes|low profile|low profile|low profile}.
What better way to do that than to spy on @{(toldmama) him|Hermes|Hermes|Hermes}? Ensure he doesn't do anything too dangerous. Or, if he does, that you can use it against him. Besides, it would be a great opportunity to find out if there's another, dodgier, reason he doesn't want Iris to go to the @{(readscroll) Archives. A reason connected to why Morpheus is keeping his own record of his correspondence with the heral|Archives}.

Finding concrete proof of his wrongdoings @{(revenge) would certainly be a neat way to make him pay for the pain he's caused|wouldn't be a bad thing, either}.

Though you could also ignore your mother's wishes and address him directly. If you manage to get through to him, it could put a stop to his antics, perhaps even hold him accountable for them.

And if you don't, well, perhaps @{(revenge) you'll resolve this the old-fashioned way. An eye for an eye and all that|you could use them as leverage}.

So, what will it be?

*choice
    #I'll talk to Hermes in a bid to understand his behavior.
        *if diplomacy > 55
            *set respect %+10
            *set pantheonplayer %+15
            *set olympusinfluence %+10
            *set tbc true
            *goto main60
        *else
            *set hermesoutcome 1
            *set respect %-10
            *set pantheonplayer %-10
            *set olympusinfluence %-15
            *set parents %-10
            *goto main60
    #I'll confront Hermes and demand an explanation for his behavior.
        *set confronthermes true
        *if leadership > 55
            *set respect %+5
            *set olympusinfluence %+10
            *set underworldinfluence %+10
            *set tbc true
            *goto main60
        *else
            *set hermesoutcome 1
            *set respect %-15
            *set olympusinfluence %-10
            *set parents %-10
            *goto main60
    *if revenge
        #I'll intimidate Hermes and exact retribution for his behavior.
            *set cameathim true
            *if charm < 40
                *set olympusinfluence %+10
                *set underworldinfluence %+10
                *set tbc true
                *goto main60
            *else
                *set respect %-15
                *set olympusinfluence %-10
                *set underworldinfluence %-10
                *set pantheonplayer %-10
                *set hermesoutcome 1
                *goto main60
    #I'll spy on Hermes to uncover proof of his behavior.
        *set spiedonhermes true
        *if stealth > 55
            *set underworldinfluence %+15
            *set maverickgoddess %+10
            *set parents %+10
            *set hermesoutcome 3
            *goto main60
        *else
            *set hermesoutcome 2
            *set maverickgoddess %-10
            *set underworldinfluence %-10
            *set olympusinfluence %-10
            *set caughtbyhermes true
            *goto main60

*label main60

*if morpheuswith
    *goto prehermes1
*else
    *if spiedonhermes = true
        You press your back against one of the modest homes leading to the alleyway, and wait for your fellow Messengers to finish their conversation.

        "As you wish," the aide tells Hermes, their voice drawn.

        You hear the flap of wings and glance at the sky, where Iris and Hermes part ways. The aide towards the heart of the town, the herald towards the sea.
        *goto spyingonhermes1
    *else
        This ends here and now.

        "As you wish," you hear the aide tell Hermes, their voice drawn.

        Then they take off, white wings cutting through grey sky, just as you hurry onto the deserted street.
        *goto hermeschat

*label prehermes1

But first, you should deal with Morpheus. His eyebrow has crept all the way to his hairline, and somehow grown even more judgemental.

"I was simply going to @{(spiedonhermes) follow him|have a little chat with him}," you sigh.

*if spiedonhermes
    "Oh." He blinks away his surprise. "That's rather smart. In fact, it's what I'm here to do."

    "Then perhaps I should switch up my strategy."

    You expect him to accuse you of pettiness. "Or perhaps we could join forces," he offers instead.

    It's your eyebrow's turn to arch. "Since when do you do team work?"

    He shrugs, but there's nothing casual abut the way he's looking at you. "Since I realized how good a team we make."

    *choice
        #I accept. I wouldn't mind spending some more time together.
            *set Morpheus %+10
            *set morpheusalong 2
            *goto acceptmorpheus
        *if revengereason = 2
            #I accept. I'm doing this for him, after all.
                *set Morpheus %+15
                *set morpheusalong 2
                *goto acceptmorpheus
        #I accept. I could use a hand going up against such a powerful deity.
            *set Morpheus %+5
            *set cunning %+5
            *set morpheusalong 2
            *goto acceptmorpheus
        *if revengereason != 2
            #I accept. I can always throw him under the bus if I need to.
                *set Morpheus %-5
                *set ruthless %+5
                *set morpheusalong 2
                *goto acceptmorpheus
        *if unsureaboutmorpheus
            #I refuse. I don't think we make a good team at all.
                *set Morpheus %-15
                *set morpheusalong 3
                *goto rejectmorpheus
*else
    *set morpheusalong 4
    *set foolish true
    He crosses his arms. "See? Foolish."

    "We'll see about that," you snarl, storming out of the home.

    You've already wasted too much time talking to him.
    *goto prehermeschat

*label rejectmorpheus

"Absolutely not," you tell him, lifting your chin.

*if revengereason = 2
    You may be doing this for him, but you don't have to do it [i]with[/i] him.
    *goto rejectmorpheus1
*else
    *goto rejectmorpheus1

*label rejectmorpheus1

"Suit yourself," he scoffs, gathering his wings around him. "But when I beat you to whatever it is Hermes is hiding, don't say I didn't try."

"Oh, I won't," you assure him, turning your back on him with what you hope is a very dignified huff.
*goto spyingonhermes

*label acceptmorpheus

"I suppose you could tag along."

His lips twitch upwards. Not quite a smile but not far-off.

*label spyingonhermes
*page_break

You tipote back onto the alley. 

Iris and Hermes are already aloft. The aide headed towards the heart of the town, the herald towards the cloud of smoke looming over it.

@{(morpheusalong) NA|"Coast is clear," you tell Morpheus once the ash has swallowed Hermes.|You follow after the ash swallows him, not bothering to look back.|NA}

*label spyingonhermes1
*page_break Fly to Olympus

Slowly and silently, taking your time and keeping your distance, you follow Hermes to the Cloud Gate. Through the ivory pillars you go, then across the grove, sparing a quick thought for the drakon hatchlings.

@{(morpheusalong) If nothing else, they're in good hands|"Why does it have to be so aggressively bright?" Morpheus mutters under his breath|Morpheus is close behind you. You can feel it, like a wind carrying a bad scent|na}.

This time, there's no welcoming party awaiting you by the palace. Only a bustling army of nymphs and satyrs carrying supplies to a long line of carts stretching beyond the portico. Carts that will no doubt be hauled to Hellas for the feast. 

Until then, they provide excellent hiding spots for you to tail Hermes all the way to the Archives.

*page_break

The tall, round building is adjacent to the palace, and just as grand. Built on lofty, ribbed columns, and canopied by a golden dome surrounded by clouds. You hurry up the steps leading to its arched @{(morpheusalong) entrance| entrance. Morpheus moves like a shadow beside you, creeping from column to column without making a sound|entrance|NA}.

@{(morpheusalong) Once inside, you have to smother a gasp|"That's better," he whispers once inside|Once inside, you have to smother a gasp|NA}.

@{(morpheusalong) It's a striking space|It's certainly less bright in here. More breezy, too. And striking|It's a striking space|NA}. You've never been here before. You've never had the need. Iris carries your scrolls back and forth, and perusing records isn't part of your ever-growing list of duties.

Still. You can't help but marvel at the rows upon rows of shelves stretching in every direction. Each of their nooks is stuffed with neatly rolled scrolls, golden edges glinting under the dome. 

It isn't as radiant, when you're under it. Its glow has a gentle amber hue that reminds you of dying embers, or the last stages of a sunset, and gives the archives a warm, cosy feel.

It's rather romantic.

*fake_choice
    *if morpheusalong = 2
        #I wonder if Morpheus thinks the same. 
            *set Morpheus %+5
            You steal a glance at him and @{(demure > 55) blush|grin}.
    *if morpheusalong = 3
        #I wonder what Morpheus will make of it.
            *set Morpheus %+5
            He must be close by, skulking in some dark corner, waiting–hoping–for you to fail.
    *if aresoutcome > 2
        #I wonder what Ares would make of it.
            *set Ares %+5
            Perhaps you'll bring him next time the pair of you sneak away together.
    *if theronoutcome > 2
        #I wonder what Theron would make of it.
            *set Theron %+5
            Would the dome's design call to him in his dreams like the ship's had? Would his hands itch to replicate it, his mind fill with ideas on how to enhance it?
    #I wonder what secrets they hide.
        *set cunning %+5
        There must be some real juicy stuff among all these official records and divine correspondence.
    #No wonder Iris wanted to sack off soul guiding.
        *set dutiful %-5
        This is much more peaceful, and far less work.
    #I don't dwell on it. I'm on a mission.
        *set leadership %+5

Hermes begins to whistle in the distance, drawing your attention. 

Unlike the courtyard, the Archives are deserted, giving even the tiniest noise free rein of the scroll-stuffed aisles. You @{(flightstyle) tuck your wings in, tiptoeing|suppress your shadows, tiptoeing|tiptoe} following the sound.

*if hermesoutcome = 2
    It leads you west, then north, then west again.

    @{(morpheusalong) You glance through the gaps in the shelves and read|Morpheus is close behind you, glancing through the gaps in the shelves and reading|You glance through the gaps in the shelves and read|na} the section labels, trying to keep track of your bearings.

    But the archives are a labyrinth, and there's no thread to lead you in the right direction, and no sign of Hermes, other than that damned whistling.

    You're almost panting by the time you hit a dead end; a curved marble wall at the end of a narrow aisle flanked by shelves on either side.
    *goto prehermesconfrontation
*else
    Until @{(morpheusalong) you see him|Morpheus halts and gestures for you to do the same|you see him|na}.

    There. Up ahead, fluttering towards a section labelled 'Messengers' Council.' 
    *goto spyingonhermes2

*label spyingonhermes2
*page_break Hermes

You take cover in the adjacent @{(morpheusalong) aisle, watching|aisle. Morpheus follows, moving as quietly and as deftly as you do. When you catch up to Hermes, you watch|aisle, watching|na} him through the gaps in the shelves.

Still whistling his merry little tune, he begins plucking scrolls from one of the nooks and dropping them on the marble floor.

Four scrolls in total land with a dull thud, and go up in flames when Hermes clicks his fingers. They burn fast, the smell of smoke barely infiltrating the air.

Once they've reduced to a pile of dust, the herald promptly shoves their remains under the bottom shelf with his sandal. He then retrieves four fresh scrolls from his satchel and slots them into the same nook, exactly where the others had been.

Satisfied, he turns around and begins making his way back down the aisle.

*page_break

When he reaches the section you're hiding behind, the whistling stops, as do the wings at his brow.

@{(morpheusalong) You move fast, crouching just|Morpheus crouches, pulling you down|You move fast, crouching just|na} in time to avoid his notice.

There's a pause, a terrible moment where you fear you're done for. Where you fear you'll burn next.

Then the whistling resumes, growing fainter and fainter until it's gone.

*page_break Phew

@{(morpheusalong) Relieved, you double back to the spot Hermes had been in|"That was close," Morpheus breathes|Relieved, you double back to the spot Hermes had been in|na}.

@{(morpheusalong) Slowly, pausing to listen out for signs of anyone approaching|You nod, allowing yourself a moment to enjoy the relief washing over you. Then you double back to the spot Hermes had been in|Hastily. Morpheus must be close by|na}.

The new scrolls are easy to recognize. Unlike the others, they aren't covered in a layer of dust. You pore over their contents with shaking hands. Some are addressed to Morpheus, others to you. You recognize the instructions of neither. 

There's no mention of Leukas, or the other patronless cities Hermes has been asking you to target.

This is why Morpheus was copying the scrolls. Keeping his own record of Hermes's messages, in case he was altering the official one.

*if morpheusalong = 2
    *goto morpheusarchives
*else
    Clever. 

    And exactly the kind of proof you needed. The kind of proof @{(revenge) that will see Hermes is punished|your mother is after. And that will give you leverage}.

    You tuck a few of the scrolls away and smile.

    *if theronoutcome != 2
        *goto warntheron
    *else
        Where to next?
        *goto theronchoice

*label morpheusarchives
*page_break

"I knew it!" he exclaims, startling you into almost dropping a scroll. "I knew he was lying. Doing this for his own benefit. Not that I believe Zeus will do anything about it. It got him his worship, and that's all that brute cares about."

Dangerous words, uttered in Zeus's very palace no less. But will they turn out to be true?

"Maybe not if we're the ones delivering it. But if the Queen of the Underworld tells him, do you think he could deny [i]her[/i]?"

He considers it, but not for long. "Only a fool would."
    
You tuck a few scrolls away. They're exactly the kind of proof you needed. The kind of proof @{(revenge) that will see Hermes punished|your mother is after. And that will give you leverage}.

It's a good thing, too, for Morpheus's next words would've defintiely made you drop them. 
    
"I owe you an apology."

Your gaze snaps to his. He doesn't flinch away from it. Doesn't even sound too pained when he adds, "I was out of line earlier. I was worried about what Hermes might do to you if you confronted him. It's no excuse, and I'm sorry. How can I make it up to you?"

He looks it too. That's new. As for how he can make it up to you, he can start by

*choice
    #Kissing me against these shelves.
        *set Morpheus %+10
        *set closetomorpheus true
        "I have an idea," you say, grabbing his chiton and pulling him towards you.
        *goto kissingmorpheus
    #Grovelling some more.
        *set ruthless %+5
        "For me to even consider forgiveness, I'm going to need you to do better than that." You cross your arms. "Much better."

        Irritation pokes at his calm facade, but it doesn't destroy it. Not yet. He clears his throat and, in a tone that only has a hint of sharpness, he says, "${name}. I am so deeply, terribly sorry. Not only was I out of line earlier, I was wrong."
        
        "As you often are," you cut in. 

        "As I often am," he repeats through gritted teeth. "It doesn't matter that I acted out of concern, nor that I was afraid of what might happen to you. It was unacceptable, and it won't happen again. Satisfied?"

        You shrug, delighting in how much it bothers him. "It will do."
        *goto morpheusmoment1
    #Owing me a massive favor.
        *set cunning %+5
        *set morpheusowesyou true
        "You can make it up to me with a favor I can call in whenever I want. No questions asked."

        He bristles, but he doesn't deny you. "Deal."

        "Excellent."
        *goto morpheusmoment1

*label prehermesconfrontation
*page_break Great

You realize you've been lead here on purpose too late.

"Has nobody taught you Chthonic deities manners?" Hermes says behind you. "Here in Olympus, it's considered rude to spy on your superiors. Especially when you're so loud and obvious about it."

@{(morpheusalong) You|You both|You|na} whip around to find the herald blocking the aisle, looking pleased as a cat who's just cornered a mouse.

"Not as rude as stealing worship and unleashing a giant on your fellow Messengers," you say with as much surety as you can muster.

But he merely chuckles. 

"I know you did it," you add, failing to quell your annoyance.

*if (injured = true) and (scar !=3)
    His gaze trails down to your scar and his lips twist into a grin.
    *goto hermesconfrontation
*else
    *goto hermesconfrontation

*label prehermeschat
*page_break

You hear the flap of wings. Iris streaks the grey above you with color as you pick up the pace.

*label hermeschat

"Hermes, wait!" you call out.

*page_break

The herald hovers above the road, both sets of wings beating the air. At the sight of you, surprise darts across his face.

*if (injured = true) and (scar != 3)
    *set noticedscar2 true
    At the sight of your scar, it turns to caution.
    *goto postscarnotice
*else
    *goto postscarnotice

*label postscarnotice

"${name}? What are you doing here?"

*if cameathim
    You lunge forward, slicing through Iris's double rainbow and slamming into the cobbles before him. 
    
    "I'm here for retribution," you snarl, leveling your fiercest glare at him. "Stealing worship, breaking prisoners out of Tartarus, making @{(revengereason) me bleed|one of us bleed|innocent mortals suffer}. You have a lot to answer for, herald."

    *if tbc = false
        But neither your stance nor your accusations appear to faze him.

        In fact, judging by the chuckle he lets out, they seem to amuse him.
        *goto hermesconfrontation
    *else 
        *goto hermesconfession
*else
    "We need to talk," you say, side-stepping Iris's double rainbow and halting before @{(confronthermes) him, tall and righteous|him}.

    His grip on his staff tightens.

    "That's unfortunate. I don't really have time for talking, you see." He waves his staff at the smoke. "I have dead to guide and scrolls to archive, not to mention a feast to help organize. I'm sure you're aware of the increased communication such an event requires. Let's talk another time, yes?"

    "I'm afraid this can't wait," you @{(confronthermes) say firmly|say, gentle but firm}. "I know, Hermes. I know you've been skimming worship meant for Hypnos. I know you were the one who released Argus."

    *if tbc = false
        @{(confronthermes) You draw yourself up, eager to appear steadfast, to channel your mother's no-nonsense tone|Despite your best efforts to appear calm, friendly even, the words have an edge to them}.

        But @{(confronthermes) it falls flat. You fall flat|Hermes isn't bothered by them}. 
        *goto hermesconfrontation
    *else
        *goto hermesconfession

*label hermesconfession

He pales beneath his wide-brimmed hat and, for a moment, you fear he might actually vomit.

A ridiculous notion–deities don't wretch. Such an unseemly bodily function is for mortals and mortals alone.

"Please…I…I can explain," he stammers, clutching the strap of his satchel.

@{(cameathim) You lean in closer and hiss, "By|"By} all means."

*label hermesconfession1
*page_break

The herald takes a deep breath, even though he doesn't need it.

"I had no choice, alright? @{(spiedonhermes) You|My fa-Zeus} kept adding to my workload. I tried telling @{(spiedonhermes) you|him} I was stretched too thin, but @{(spiedonhermes) you|he} wouldn't hear it. All @{(spiedonhermes) you care|he cares} about is the Giants, and securing enough worship to beat them." He rakes a hand down his face, but it doesn't wipe away the stress carved into it. "So yes, I skimmed some for myself, but only to keep up with @{(spiedonhermes) your|his} ridiculous demands. It's not like Hypnos was using it, and it's certainly paid off, hasn't it?"

"Maybe you should ask Morpheus that, since you unleashed a giant on him. Or perhaps the Leukans, since they had to suffer sleepless nights for @{(spiedonhermes) months," your mother cuts in firmly.|months."}

He winces. "I panicked, okay? I suspected Morpheus was onto me, and I knew he wouldn't understand. I thought perhaps an encounter with what we're up against would appeal to his sense of empathy."

"How teacherly of you," you scoff.

"As for the Leukans, I was going to stop after the feast. Once the Giants were dealt with. I need this. [i]We[/i] need this. Don't you understand?" His tone turns pleading, his expression desperate. If it's an act, it's a rather convincing one.

*if spiedonhermes
    *gosub_scene subroutines punishmentchoice
    *goto punishmentchoice1
*else
    *goto hermesdecision

*label hermesdecision

*if toldmama = 3
    Right now, you're the only deity with this knowledge. What will you do with it?
    *goto hermesconfession2
*else   
    "I'm afraid the net is closing in," you tell him, making him pale further. "@{(argusdead) Argus confessed|It is only a matter of time before my parents break Argus and he tells them you helped him}. Morpheus survived your attempt on his life, which happened suspiciously close to your falling out. My mother is to meet Zeus tomorrow; how do you think he will react to all these findings when she presents them to him?"
    
    Though you suppose you could ensure they are presented in a less harsh light. Maybe even put in a good word for him afterwards, if you were so inclined.
    *goto hermesconfession2

*label hermesconfession2

*fake_choice
    *if toldmama = 3
        #I'll keep it to myself. I believe he acted in the realms' best interests.
            *set hermesoutcome 4
            *goto hermesfriends
    *if toldmama = 3
        #I'll keep it to myself, but only if he owes me one in return.
            *set hermesoutcome 5
            *set favor true
            "My silence will cost you," you tell him.
            *goto hermesfavor
    *if toldmama != 3
        #I'll ask for leniency. I believe he acted in the realms' best interest.
            *set hermesoutcome 6
            "I'm willing to stick my neck out for you, but it will cost you," you tell him.
            *goto hermesfriends
    *if toldmama != 3
        #I'll ask for leniency, but only if he owes me one in return.
            *set hermesoutcome 7
            *set favor true
            *goto hermesfavor
    #I'll show him no mercy. He will be brought to justice.
        *set hermesoutcome 8
        He doesn't deserve mercy, not after all the harm he's caused.

        "I understand that you will face the consequences of your actions," you say. "Now, you can either swear to me you'll hand yourself in to Zeus when we meet him tomorrow, or be dragged to Tartarus right now."
        *goto hermesconfession3

*label hermesfriends

@{(cameathim) Your hunger for revenge fades. You|You} yourself have felt the pressure of your increased @{(skimmedworship) workload, and have relied on furtive measures to increase your own worship|workload, even if you haven't stooped as low as he has to remedy it}.

*if hermesoutcome = 4
    "I understand," you sigh. "I won't rat you out. But this stops now."

    His relief seems as genuine as his desperation had been. "Thank you."
    *goto guarantees
*else
    *goto hermesagreement

*label hermesfavor

@{(cameathim) Missing out on revenge is worth it if it means having an Olympian in your debt|You can't put a price on having an Olympian in your debt}.

"Anything," he says.

"It is is decided, then. You stop this now, and you owe me a favor I can call upon whenever I please."

He nods, twirling his staff. "Deal."

*if hermesoutcome = 5
    *goto guarantees
*else
    *goto hermesagreement

*label hermesagreement

"Join us at the meeting, and I will speak on your behalf. I can't guarantee that you won't be punished, but I can ensure your circumstances are taken into consideration." 

He inclines his head. "Thank you."

*label guarantees
*page_break

"I will of course, need some guarantees in return. Stygian guarantees." You hold his stare without flinching. "An oath to ensure you'll uphold your end of the bargain."

*label hermesconfession3

His grip on his staff tightens. You tense, bracing yourself for an @{(cameathim) attack. Almost wishing for it, too. If he gives you an excuse, you won't hold back|attack}.

But coming at you so overtly isn't the same as sicking a Giant on Morpheus. If he hurts you in the open, it could make him some powerful enemies.

It could start a war.

So he merely nods, pointing his staff at the ground, and his gaze at the rainbow. "I'll swear it."

@{(cameathim) You tuck away your disappointment and grin. "Good."|"Good."}

*page_break Locate Iris

Their rainbow leads you to one of the lanes adjacent to the agora, where more funeral pyres are being built. Iris has corralled the dead whose bodies have already burned. Their specter-like shapes huddle close together, gawking at what used to be their home.

"Hermes, ${name}." They greet you. "Is everything well?"

"I must swear an oath," Hermes answers. Straight to the point, as per usual. "Now."

Iris frowns, eyes flickering between amber and blue. But they pull out the waterskin and carefully peel it open. The scent of metal woven with brine pierces the air, clinging to the back of your throat. The dead stir, turning their hollow gazes away from the waterskin. They would've turned their spectral backs on it too, if Iris hadn't soothed them. 

"It's alright," they murmur. "It won't hurt you."

But it will hurt Hermes, if he dares break his oath.

Now you now just how much, too.

*page_break Witness His Oath

"Let Iris, messenger deity and master of the rainbow, bear witness to my oath and keep it safe lest I break it," he begins. Then he's grinning, and suspicion rises inside you like bile. Or perhaps it's fear. "I hereby swear upon the river Styx that, so long as ${name}, daughter of Hades and Persephone, Mistress of Nightmares @{(hermesoutcome < 5) speaks on my behalf with conviction and confidence|keeps my secret},
*if (hermesoutcome = 4) or (hermesoutcome = 5)
    I will not engage in unsanctioned worship extraction @{(favor) schemes and be in her debt. A single favor, which can be called upon whenever she pleases, and which I will do everything in my power to grant|schemes}."
    *goto hermesconfession4
*elseif hermesoutcome = 8
    *set tricked true
    I will cease all unsanctioned worship extraction schemes, and appear before my father to confess to all my wrongdoings."

    Before you can protest, they yank the waterskin from Iris's hands and chug, tying you to the oath as much as he tied himself. If you don't support him before Zeus, he won't be beholden to this oath.
    *goto hermesconfession4
*else
    I will appear before my father and confess to all my @{(favor) wrongdoings. In exchange for her support, I will be in her debt. A single favor, which can be called upon whenever she pleases, and which I will do everything in my power to grant|schemes}
    *goto hermesconfession4

*label hermesconfession4

Iris stiffens, glancing between you and the herald, but they don't say a word. They can't. Their duty is to bear witness to the oaths, not pass judgement on them.

@{(tricked) But this isn't over. You also now how to play dirty|"Not so fast," you warn Hermes before he can take the waterskin from them}. "Guarantees also includes safety. My safety, and that of those who I care about."

Hermes rolls his eyes, but obliges. "I also swear that neither ${name}, weaver of nightmares, nor those she cares about, will suffer any harm at my hands in retaliation. Satisfied?"

"It will do," you sigh, glancing at Iris. 

"So it shall be," they say, handing the waterskin to Hermes without meeting your eye.

The herald takes @{(tricked) another|a} swig, grimacing after he swallows.

"Off you go," Hermes tells Iris, returning the waterskin.

Iris nods and, despite their clear concern, proceeds to coax the quivering dead into the sky with kind words and gentle movements.

Hermes waits until they're gone to regard you anew. @{(hermesoutcome) na|na|na|"Thank you," they repeat.|"Thank you," they repeat.|"Thank you," they repeat.|"Thank you," they repeat.|"I guess I'll see you tomorrow," he sighs} before taking to the sky himself.

*if morpheusalong = 4
    You watch him disappear into the cloud, rather pleased with yourself.
    *goto morpheusmoment
*else
    *if theronoutcome = 2
        *goto theronchoice
    *else
        *goto warntheron

*label hermesconfrontation

@{(morpheusalong) He raises an eyebrow at you, entirely unfazed|He raises an eyebrow at Morpheus, who tenses beside you|He raises an eyebrow at you, entirely unfazed|He raises an eyebrow at you, entirely unfazed}. "Do @{(cameathim) I|you}, now? Do you have any proof of such preposterous claims?"

*if argusencounter = 3
    You gather as much @{(confronthermes) authority|poise} as you can muster and answer, "Argus confessed." 

    "Oh, dear. And the giant himself can substantiate that, yes?"
    *goto hermesconfrontation1
*else
    *goto hermesconfrontation1

*label hermesconfrontation1

You scramble for an answer–and come up empty-handed.

*page_break

@{(cameathim) The fight goes out of you, taking your nerve with it|The extent of your foolishness becomes all too clear}.

What were you thinking, @{(spiedonhermes) attempting to sneak up on the sneakiest deity of all|going after him like this}?

Hermes senses your frustration and smiles. "That's what I thought."

"I…"

But the herald is on you before you can salvage your pathetic attempt at @{(cameathim) intimidation|dialogue}. The tip of his staff presses into your chest as he draws himself to his full height.
Which, it turns out, is quite considerable when he isn't hunched over his satchel or wriggling around like a winged snake.

"Word of advice, nightmare weaver. I would caution against crossing whoever is responsible for the dreadful things you speak of. Who knows what they might do in response, or who they might hurt @{(theronoutcome) next. I hear you've grown rather close to a mortal lord. You know how breakable those are.|next.|next. I hear you've grown rather close to a mortal lord. You know how breakable those are.|next. I hear you've grown rather close to a mortal lord. You know how breakable those are.|next. I hear you've grown rather close to a mortal lord. You know how breakable those are.|next. I hear you've grown rather close to a mortal lord. You know how breakable those are.}" 

He pauses to @{(morpheusalong) grin.|grin at Morpheus. "Perhaps they'll finish this one off. His wing isn't looking too good, is it?"|grin. "Perhaps they'll finish Morpheus off. I hear he was greatly injured in a brutal attack. He might not survive another."|grin. "Perhaps they'll finish Morpheus off. I hear he was greatly injured in a brutal attack. He might not survive another."}

@{(morpheusalong) Fear rears up inside you|Morpheus steps between you, forcing Hermes to remove his staff. "Back off," he warns|Fear rears up inside you|Fear rears up inside you}. 

Hermes's grin @{(morpheusalong) widens|widens, and though Morpheus has managed to push him back some, his gaze hasn't strayed from yours|widens|widens}. 

@{(aresoutcome) "Perhaps they'll take a swing at my half-brother. Such a sweet and gullable god, Ares is. So easily led astray."|"Think on it."|"Perhaps they'll take a swing at my half-brother. Such a sweet and gullable god, Ares is. So easily led astray."|"Perhaps they'll take a swing at my half-brother. Such a sweet and gullable god, Ares is. So easily led astray."|"Perhaps they'll take a swing at my half-brother. Such a sweet and gullible god, Ares is. So easily led astray."}

*page_break

The threat feeds your fear. It thrashes against your rib cage, 
*if morpheusalong = 1
    even after the herald removes his staff.
    *goto postconfrontation
*elseif morpheusalong = 2
    despite Morpheus's attempts to shield you. If you thought he looked defiant squaring up to the herald in the cave, you were wrong.

    This is what defiance looks like. And what it sounds like, too.

    "I said back off," he seethes.

    It's enough to make the herald's careless act fray at the edges. He twirls his staff around, but his grin isn't so wide anymore, his movements more jittery.
    *goto postconfrontation
*else
    until a familiar voice @{(spiedonhermes) echoes|speaks} behind you.

    "Get away from her."

    Morpheus.

    "Right on cue," Hermes quips, removing his staff. "Welcome, son of Hypnos. We were just talking about you."

    He shoots you a wink.
    *goto morpheusconfrontation

*label morpheusconfrontation
*page_break

Morpheus lands beside you. If you thought he looked defiant squaring up to the herald in the cave, you were wrong. This is what defiance looks like. And what it sounds like too.

"About how I'll end you if you don't back off?" he seethes.

"I've always enjoyed your sense of humor." The herald twirls his staff around, but his composure is fraying at the edges. His grin isn't so wide anymore, his movements more jittery. "About what happened to your wing."

Its scarred pane twitches, but the rest of him is motionless.

*label postconfrontation

"Anyway. @{(spiedonhermes) Nice of you to drop by,"|Good talk,"} Hermes quips cheerfully.
*if spiedonhermes
    "Now, you better find your way back home–and promptly–otherwise I'll be forced to call security. Harpies don't take kindly to tresspassers, or spies."
    
    He steps out of the way, and you hurry out of the building, grateful to put some distance between you and his threats.
    *goto postconfrontation1
*else
    "Now, if you'll excuse me, I have work to do."

    He skitters off, disappearing into the black clouds above.
    *goto postconfrontation1

*label postconfrontation1

@{(spiedonhermes) But even after you reach the gate and are back in Hellas|But} your fear remains.

*if morpheuswith
    "Are you alright?" Morpheus asks. All the bluster seems to have fled from him too.

    @{(foolish) There's no smugness about being right, no lecturing you about how foolish you are. There's|There's} only concern in his face as he checks you over, close enough that the tip of his wing brushes your shoulder.
    
    *choice
        #I fold into his arms; I need comfort.
            *set Morpheus %+10
            *set closetomorpheus true
            They're ready and waiting. He wraps them around you, pulling you into his chest.

            You hold onto him tight, listening to the faint, steady beat of his heart as he runs his fingers through your hair. The gentle touch chases your fear away. @{(morpheusoutcome) na|na|It feels intimate in a way you didn't know anything with Morpheus could feel|It feels more intimate than kissing him had|This too, is more intimate than anything you did on his throne|}.
            *goto morpheusmoment1
        #I throw myself at him; I need distraction.
            *set Morpheus %+5
            *set distraction true
            *set closetomorpheus true
            You grab his chiton and haul him towards you.
            *goto kissingmorpheus
        #I step away from him; I need clarity.
            *set Morpheus %-5
            "I will be," you tell him, leaning away from his touch.

            He jerks his wing away and clears his throat. "Don't let him rattle you. We'll figure something out."

            You're not so sure, but you can't dwell on it right now.
            *goto morpheusmoment1
*else
    *fake_choice
        #I allow myself to feel it so I can move past it.
            *set leadership %+5
            So you tell yourself, anyway.
        #I refuse to succumb further to its grip.
            *set ruthless %+5
            So you tell yourself, anyway.
        #I wish I had listened to my mother.
            *set parents %+5
            Too late for that now.
        *if aresoutcome != 2
            #I think of Ares and it grows stronger.
                *set Ares %+5
                He must be feeling better now. Sharper, and able to defend himself, if Hermes makes a move on him. You wont underestimate him the way his family does–the way Hermes will. But that doesn't stop you from worrying.
        *if theronoutcome != 2
            #I think of Theron and it grows stronger.
                *set Theron %+5
                You must check in on him at once.
    
    *if theronoutcome != 2
        *goto warntheron
    *else
        Better to focus on something else. Like your next move, for example.
        *goto theronchoice

*label kissingmorpheus

He gasps into your mouth, caught off guard. But his shock is short-lived. 

When he kisses you back, he does so @{(distraction) gently, carefully. You press further into him, burying your hands in his impossibly silky hair|with pure abandon. He hauls you up, hands pressing into your hips, shelves pressing into your back}.

@{(distraction) Right now, you need to feel something other than fear|Just like you wanted. You grin against his lips, burying your fingers in his impossibly silky hair}.

@{(distraction) Something like the heat coursing through you when he gives in and molds your body to his|"Remind me to apologize to you more often," he whispers against your neck before kissing you again}.

*if morpheusoutcome = 3
    *set justkissedmorpheus true
    *set laterkiss1 true
    *gosub_scene subroutines morpheuskiss
    *goto kissingmorpheus1
*else
    *goto kissingmorpheus1

*label kissingmorpheus1

*if hermesoutcome = 2
    *goto interrupted
*else
    Soon, your dread is retreating. By the time he pulls away and cups your face, it's nothing but a distant memory.
    *goto morpheusmoment1

*label interrupted
*page_break Then Someone Shrieks

"What do you think you're doing?"

You peer over Morpheus's shoulder to find a goddess glowering at you through a pair of golden spectacles.

"This has got to stop happening," Morpheus laments, grudgingly putting you down and turning to face her. "What does it look like we're doing, Muse?"

Muse. This must be the Clio Iris mentioned. The keeper of the Archives. No wonder the aide was so keen on paying her a visit. She's beautiful. Tall and voluptuous, brown skin glowing under the amber light of the dome, black hair braided and beaded into a beautiful crown at the top of her head.

More importantly, she's furious.

"You have two seconds to get out of here before I call the harpies," she shrieks anew, stepping aside and wagging an ink-stained finger in the exit's direction.

Morpheus takes your hand and the pair of you make a run for it.

"I am so tired of this. Why do deities insist on treating this temple of knowledge like a brothel?" you hear Clio grumble as you hurry past her.

*page_break 

Something about fleeing Olympus hand in hand with Morpheus, in a hurry and as surreptitiously as possible, makes you feel giddy.

Perhaps that's why it's so hard to let go of him when you reach Hellas anew.
*goto morpheusmoment2

*label morpheusmoment
*page_break Until Morpheus Ruins It

@{(cunning > 55) "Who's the foolish one now?" you ask into the newly deserted alley|"You think that wasn't foolish?" he says, emerging onto the alley, right behind you}.

@{(cunning > 55) He emerges from the shadows right behind you, clearly annoyed that you knew he was hiding in their midst. How could you not? He's like a bad smell lingering in the wind. You can't see it, but you can't ignore it either|You wheel around, and find him casually examining one of his fingernails}.

@{(cunning > 55) "Still you," he smirks, scrambling for his usual smugness|But his casual demeanor is forced, his violet gaze sharp}. @{(hermesoutcome) na|na|na|"You're letting him get away with this?"|"You're letting him get away with this?"|"You're letting him off the hook so easily?"|"You're letting him off the hook so easily?"|"You think he's going to show up at this silly little meeting of yours?"}

@{(hermesoutcome) na|na|na|"No, I'm doing what's best for the realms."|"No, I'm doing some future-proofing. Having him in my debt will keep him in line."|"No, I'm doing what us deities seem incapable of doing. Showing soome restraint."|"What about that looked easy to you?"|"He has no choice. Unless he wants to die."}

"I hope you're right," he snaps. Then he grows quiet, and the hatred lurking beneath his stony face turns into anguish. "I @{(argusencounter) can't watch you come so close to death again|would rather you didn't come so close to death again|won't have you end up like Argus|would rather you didn't come so close to death again}."

*fake_choice
    #I cup his face, eager to comfort him.
        *set Morpheus %+10
        *set closetomorpheus true
        Your touch seems to chase away some of his torment. He closes his eyes and covers your hands with his. 
    #I smile at him, eager to reassure him.
        *set Morpheus %+5
        It only makes a small dent in the worry tearing through his face.
    #I wave him off, eager to get past this.
        *set Morpheus %-5

"That won't happen. I need you to trust me on this, alright?" you say @{(closetomorpheus) softly|firmly}.

He lets out a long, almost tired sigh. "Alright."

*label morpheusmoment1
*page_break

@{(closetomorpheus) Letting go of him is difficult, but you force yourself to do it|He straightens, as though remembering himself}.

*label morpheusmoment2

*if theronoutcome != 2
    "There's something I must do," you tell him. "Alone."

    He seems surprised to hear it, but he doesn't try to stop you.
    
    "Be careful," he says instead.
    *goto warntheron
*else
    "I must report back to your father," he says. "Will you be alright?"

    *if hermesoutcome > 3
        "Can I count on your discretion?"

        "Yes," he sighs. "But I reserve the right to gloat for all eternity when it all goes wrong."

        "It won't."

        He doesn't reply. Instead, he shakes his head and takes to the sky.

        As for your own next steps…. 
        *goto theronchoice
    *else
        "Sure."

        @{(closetomorpheus) He gives you one last loaded look before he|He} takes off, leaving you to plot your next move.
        *goto theronchoice

*label theronchoice

*choice    
    #I'll warn Theron. Just because I don't care for him doesn't mean I don't care about his people.
        *set ruthless %-5
        *set theronreason 2
        They have been through enough as it is.
        *goto warntheron
    #I'll warn Theron. It's a good opportunity to do some reconnaissance ahead of the feast.
        *set cunning %+5
        *set theronreason 3
        It won't hurt to get a lay of the land before the Giants potentially destroy it.
        *goto warntheron
    #Why would I warn Theron? Zeus is merely bestowing a great honor upon him and his people.
        *set dutiful %+5
        *set Theron %-15
        *set didnotwarntheron true
        *set zeustheron 1
        No, you will return home and prepare for the meeting with Zeus.

        Fates know it won't be an easy one.
        *goto main61

*label warntheron
*page_break Fly To Leukas

The sunlight has all but perished by the time you reach @{(leaningtowards) Theron's balcony|Leukas. Certainly past the point Theron might linger in the shipyard to marvel at the sun's descent|Theron's balcony}. 

@{(leaningtowards) But it's not the Lord you find there|And yet, the Lord isn't in his chambers|But it's not the Lord you find there}. 

@{(leaningtowards) It's his mother|His mother is|It's his mother}. Hobbled over the chest at the foot of her son's bed, pulling blankets from it and folding them into a neat pile on the rug.

She must be who Theron gets his perceptiveness from, for she addresses you even though her back is turned to you, and you've barely made a sound.

"He's settling a dispute between two tavern owners. Shouldn't be too long. In the meantime, Goddess, would you mind giving me a hand? My back isn't cooperating today."

*fake_choice
    #"Of course."
    #"What can I do?"
    #"Why not?"

You approach the bed, meeting her gaze. The light of the hearth dances on her angular face, deeply lined and framed by tightly curled, grey hair. Her eyes are a paler brown than Theron's, and her smile more crooked, but the resemblance is undeniable.

At her behest, you gather up the blankets and wait for her to rise. A long and arduous process that makes her face pucker and her bones creak. Once it's over, she leads you out of Theron's chambers and down the stairs. Those too, are a challenge.

"The name's Kleia, by the way," she huffs between groans. "I [i]may[/i] have gone a little too hard on the discus this morning. Nothing a bit of willow bark and some rest can't fix."

You frown, trying to imagine her practicing such a demanding–and dangerous–sport. It's not so hard, when you study her anew. She's strong, despite her age. Broad-shouldered and sure-footed.

Determined, too.

*page_break

She leads you out to the courtyard, where pallets have been laid out around a great hearth. Children are gathered around it, listening to a poet wax lyrical about how the hero Medea @{(beatmedea) was epically defeated by|epically defeated a} @{(disguise) hapless servant|lowly aulos|ditzy party} girl. 

They're too enraptured by the tale, and she too focused on telling it with flair, to notice your @{(beatmedea) triumphant smirk|scowl}. 

Kleia directs you to place the blankets on the pallets, then calls you back to her side. "Now, let us find a quiet place to enjoy the evening."

"You mean wait for your son?"

"Yes, that too."

*page_break

It isn't long before the pair of you are sitting at a secluded table with steaming mugs of willow bark tea between your fingers and shawls wrapped around your @{(flightstyle) wings|shoulders|shoulders}. Kleia insisted on the latter, despite your assurances that you were a goddess, and thus unaffected by the chill.

@{(theronreason) Not exactly what you had in mind when you rushed here in a panic|Not exactly what you had in mind when you rushed here in a panic|Not exactly the reconaissance you'd imagined}, but not unpleasant either.

"Grandchildren?" you ask, nodding at the children. There are at least ten of them, giggling away as the poet does a terrible impression of your @{(disguise) servant|aulos|party} girl.

Kleia shakes her head. 

"Grand nieces and nephews. Her too, Gods' bless her," she sighs, shaking her head at the poet. "Theron is an only child. And a miracle one, at that. His father and I married young, but by the time we were ready to start a family, the Fates weren't so sure we should. We had all but given up on that dream when Theron came along. And since he seems intent on delaying his own family, I must make do with spoiling my siblings' instead."

She takes a sip of her drink and asks, "What about you? You have any?"

You almost choke on your @{(virgin) tea|tea. So far, you've been very much focused on preventing them}. What do you reply?

*fake_choice
    #"Not yet. But I will, one day."
        *set children 1
        *set wantchildren true
        She nods approvingly. "Your mother must be delighted."
        
        You suppose she will be, when they do eventually arrive. You doubt she's even thought about it though. Unlike mortals, you're not on a deadline. You could fall pregnant tomorrow, or in a thousand years, and it wouldn't make a difference.
    #"Not yet. Though I might, one day."
        *set children 2
        *set wantchildren true
        She nods lightly. "No need to rush into it."
    #"Fates, no. And I never will."
        *set children 3
        "I don't blame you," she chuckles. 
        
Then she leans over the table with a conspiratorial grin and adds, "Besides, no matter how hard you try to raise them right, they might still go ahead and become a poet."

You decide then and there to:

*choice
    *if theronoutcome != 2
        #Charm her. I want her to like me.
            She's a formidable woman. Unafraid of you–and funny.
            *if charm > 55
                *set peoplepleaser %+15
                *set worship %+5
                So you get to work, regaling her with stories of the courtyard in your own palace, and the gatherings the nymphs hold there. Of @{(hobby) your weaving|your own attempts at mastering the discus|playing the aulos for them instead of reciting poems|playing games instead of reciting poems}. Of Averna's talent for impish lyrics, fuelled by nectar and disdain.
                *goto theronreturns
            *else
                *set peoplepleaser %-15
                *set worship %-5
                *set awkwardkleia true
                Or so you thought. 

                Because, despite your best efforts to befriend her, she flinches every time you move, gripping her mug tighter, and glancing at the children as though she expects you to curse them at any given moment.

                You realize her casual, bossy demeanor was an act. A way to appease you–or rather, distract you–until Theron returns. She isn't afraid of you. 

                She's petrified.

                And though you can't blame her–you're a goddess, she's a mortal–it still stings.
                *goto theronreturns
    *if theronoutcome < 3
        #Charm her. I want her to worship me.
            You have no doubt such a formidable woman knows how to offer the gods a formidable prayer.

            *if cunning > 60
                *set worship %+10
                *set peoplepleaser %+10
                *set maverickgoddess %+5
                And, soon, you're certain you'll experience it for yourself.

                A few captivating stories sprinkled with flattery, and you have her wrapped around your finger. Regaling you with tales of her grand nieces and nephews, filling up your mug whenever it runs low on tea, insisting you eat when food is brought out.
                *goto theronreturns
            *else
                *set awkwardkleia true
                *set worship %-10
                *set peoplepleaser %-5
                You will never find out, however. 

                That much becomes clear the harder you try to work her. 

                No matter how captivating your stories, how sweet your flattery, she always keeps her distance. As though she can see right through them. Right through [i]you[/i].
                *goto theronreturns
    #Level with her. I want her to beware of what's coming.
        "Look, Kleia," you say, holding her gaze. "I'm here to share something important. Zeus is set to visit the island tomorrow
        *if diplomacy > 60
            *set peoplepleaser %+5
            *set worship %+5
            and will be delivering some news that might be upsetting. I need you to be ready."

            "I'm listening," she says, leaning in closer.
            *goto theronreturns
        *else
            *set awkwardkleia true
            *set peoplepleaser %-5
            *set worship %-5
            and–"

            "[i]Zeus[/i]?" she practically cries. "I know you are probably much older than I am in years, Goddess, but do not mistake my relative youth for naivety. Do you really expect me to believe the King of Olympus is visiting Leukas?"

            She erupts into laughter before you get the chance to reply. "What could he possibly want with our little island?"

            "It's true," you manage while she's wiping away her tears.

            Something about your expression must've finally convinced her, because she reels back as though you struck her. "Oh."
            *goto theronreturns
    #Keep my distance. I don't want to muddle the water.
        Things between you and Theron are @{(theronoutcome) strictly platonic|strictly professional|muddy enough as it is|muddy enough as it is|muddy enough as it is|muddy enough as it is}.

        Worse, you're a goddess and she's a mortal. This kind of comradery, of casualness, is extremely improper. 

        *if dutiful > 50
            *set awkwardkleia true
            *set olympusinfluence %+5
            *set underworldinfluence %+5
            You shake off the blanket, letting it fall to the ground, and straighten. "When will Theron be back?"

            Kleia glances between your face and the discarded blanket, gaze sharpening.

            "Soon," she sighs. 
            *goto theronreturns
        *else
            *set peoplepleaser %+10
            *set olympusinfluence %-10
            *set underworldinfluence %-10
            And yet, despite your best effortts to remain indifferent, you can't help but enjoy her company. 

            She makes it all too easy, regaling you with stories of her grand nieces and nephews, filling up your mug whenever it runs low, insisting you eat when food is brought out.

            You've never eally cared about propriety. Why start now?
            *goto theronreturns

*label theronreturns
*page_break

By the time Theron returns with his father in tow, @{(awkwardkleia) you've resorted to watching the child who's taken over as storyteller in tense, awkward silence, and are grateful when the others erupt in excited screams|you're engaged in deep conversation, completely unaware that one of the children has taken over as storyteller until the rest erupt in excited screams}.

They charge him, ignoring their great uncle, and engulfing Theron in a swarm-like hug which appears to irritate him and delight him in equal measure.

"Who have we got here?" the Lord's father asks, shuffling over to your table and taking a seat next to his wife.

"Agathon, don't be ridiculous. She's clearly a goddess," Kleia reprimands him.

He squints at you, scratching at his white beard. "Oh, yes. I see now. Forgive me, Goddess. My eyesight isn't what it used to
*if theronoutcome < 3
    be."
    *goto theronreturns1
*else
    be. My son's told me all about you. Hard to get him to talk about anything else, these days."

    The table shakes when Kleia kicks him under it.

    "Ouch!" He yelps, training an accusatory glare on his wife. "What'd you do that for?"

    "I didn't do anything! I told you to stop being ridiculous," she beams, pressing a kiss to his cheek and whispering, "And keep your mouth shut, will you? We don't want to embarrass him."
    *goto theronreturns1

*label theronreturns1
*page_break

"Hello, Goddess." 

Theron perches at the edge of the table, free from the children and watching you with a mixture of surprise and @{(theronoutcome) caution|caution|caution|delight|delight|delight}. "To what do I owe the honor?"

"We have to talk," you tell him.

"That's our cue," Kleia says, shooting Theron a concerned glance. "Agathon, dear, get up. Let's settle into our pallet and listen to Alexis butcher her next story."

"I just sat down," he complains. But even then, he does as she asks, taking hold of her hand as they shuffle to the hearth.

*page_break

"Sorry about them," Theron sighs, crumpling into the bench they vacated.

He looks well-rested. You suppose not plaguing his dreams with nightmares for weeks on end would do @{(theronreason) that. Shame you're about to unleash a different kind of nightmare on him|that. Shame you're about to unleash a different kind of nightmare on him|that}.

*if (injured = true) and (scar != 3)
    "That's new," he adds, eyeing your @{(theronoutcome > 2) scar. He says it casually, but you recognize the concern in the tight line of his shoulders, the slight press of his lips|scar}.

    "It is." You glance at his neck, where his own scar glints under the firelight. "Perhaps we can exchange how we got them later."
    *goto theronreturns2
*else
    "Is everything alright?"
    *goto theronreturns2

*label theronreturns2

"Zeus has chosen Leukas to host a feast in honor of spring. A feast that will be attended by Giants," you say.

He clenches his fists. If you weren't a goddess, you wouldn't have heard his heartbeat break into a sprint, nor his breath catch in his throat. But they do, and it's only after he takes a sip of his mother's tea that they settle enough for him to speak. 

"And here I thought we were finally in the clear. Heroes gone, sleep restored." His eyes dart towards the children and he blanches. "Is our home to become a battleground, my people mere pawns?"

*fake_choice
    *if theronoutcome > 2
        #I reach for him, even though I shouldn't.
            *set Theron %+10
            *set heldhands true
            You lean across the table and take his hands in yours. He shifts his focus back to you, calloused palms gently pressing against your fingers.
    #I take a sip from my drink, hoping it comforts me too.
        *set ruthless %-5
        @{(theronreason) You hate to see him this upset, even if he has every right to be|You hate to see him this upset, even if he has every right to be|Yes, their fate is none of your business, but that doesn't mean you have to enjoy witnessing his distress}.
    #I give him some time to process it, even if there's more.
        *set diplomacy %+5
    *if theronoutcome < 2
        #I stifle my growing impatience. I have more to tell him.
            *set Theron %-10
            @{(theronreason) While you pity him and his people, you|While you pity him and his people, you|You} don't have all night.

"Zeus will announce it tomorrow. He'll descend upon the island at sunset bearing gifts, and bestow this as a great honor," you continue.

@{(heldhands) You can feel his pulse leap against your skin|His pulse beats hard against his neck}. @{(toldtheron) "Is this because of Hermes? Was he targetting us to see if we could handle it?"|"Is this why we were being punished? To see if we could handle it?"}

You shake your head. 
*if (hermesoutcome < 3) and (theronoutcome != 2)
    Hermes's threats haunt the back of your mind.

    @{(toldtheron) "No.|"No. This has nothing to do with that.} If anything, Zeus choosing Leukas to host his feast will @{(toldtheron) keep him off your back|ensure your people can rest}."
    *goto wantheron1
*else
    @{(toldtheron) "No, this is different. If anything, this has made his lying harder to maintain. Hence the lack of nightmares recently.|"No. Zeus had nothing to do with that.} Besides, I'm handling it, and you won't need to worry about it for much longer."
    *goto  wantheron1

*label wantheron1

"I suppose you don't mistreat a lamb before you sacrifice it. You let it roam the prettiest fields and feed it the sweetest apples," he laments.

@{(heldhands) You give his hands a squeeze. "You're|"You're} no lamb."

"No. To a Giant, I'm but an ant."

@{(theronreason) Perhaps. But you won't let him go down without a fight. What do you suggest?|Perhaps. But his people deserve he put up a fight. What do you suggest?|"Perhaps." You get to your feet and leave him with the following pearl of wisdom:}

*choice
    #"You should establish escape routes so your people can be evacuated if things get ugly."
        *set ruthless %-5
        *set zeustheron 2
        *goto warntheron2
    #"You should inform your generals so they're ready to fight if things get ugly."
        *set charm %-5
        *set zeustheron 3
        *goto warntheron2
    #"You should host Zeus with great pomp and circumstance so he softens towards you."
        *set charm %+5 
        *set zeustheron 4
        "Why do I feel like doing that with the heroes is what landed us here in the first place?" he wonders.

        "You may be right. But it's also what will get you out of this alive."
        *goto warntheron2
    *if theronreason > 1
        #"You should clean this place up so it's at least halfway decent for hosting divinity."
            *set Theron %-15
            *set zeustheron 5
            "Yes, Goddess," he says. His shoulders droop, and you suddenly realize how wan he looks. 
            
            @{(ruthless > 55) Mortals. So fragile. So breakable.|It saddens you, but there isn't much else can do for him}.
            *goto premain61

*label warntheron2

The words put a dent in his moroseness. You can't read his mind like you did his pulse or his heartbeat, but you can feel it snap into action. 

If you found him in the Halfrealm tonight, you have no doubt this is what he'd be dreaming of. Plotting and planning and perfecting the best strategy so that the feast's outcome works out in his favor, and that of his people's.

@{(zeustheron) na|"Use the catacombs, move some ships to the East coast ready, work on supplies,"|"Co-ordinated ranged attacks, stealth and cover,"|"A welcoming party, as many sacrifices as we can spare–which isn't many–but perhaps some sort of elaborate performance could make up for it,"|na} he says. The more he talks the surer he sounds.

@{(theronreason) "There's the practically-minded Lord I know,"|"There's the practically-minded Lord I know,"|"That'll have to do,"} you
*if theronoutcome < 3
    @{(theronreason) beam|beam|sigh}, getting to your feet.
    *goto premain61
*else
    beam.

    His smile carves lines beneath his beard and around his eyes. You realize, then, how far into the table you've both moved. As though you're bodies call to one another without your minds noticing it.

    "I should go wake my advisors. There's much to plan ahead of Zeus's arrival, and no time to plan it," he says. But he remains right where he is, @{(heldhands) with his hands firmly in yours|grazing your hand with his fingers}.
    
    "I should leave you to it, then," you say. Besides, this island will be crawling with deities come dawn. If you're still here, they might realize Theron means more to you than he perhaps ought to. That information in the wrong hands could come back to bite you. Or, more likely, bite Theron.

    But you remain right where you are too.
    *goto theronmoment1
    
*label theronmoment1
*page_break

@{(wishing) "I once told you I'm a practical man. Boasted about how I try not to waste time wishing for things that can never be."|"I'm a practical man. I try not to waste time wishing for things that can never be. Most of the time."} @{(heldhands) He traces circles on your knuckle with his thumb|His fingers brush yours}. "And yet here I am, wishing things were different. Wishing we could build a pallet by the hearth and be subjected to my cousin's terrible poems. Wishing we could fall asleep under the stars and our biggest worry when we woke was not burning the honey bread."

He's looking at you like he had in the agora, bathed in moonlight, full of hope. He'd wanted to pretend that night, too. @{(theronoutcome) na|na|But you hadn't let him|As did you. Even if only for the duration of a kiss|As did you|As did you}.  

*fake_choice
    #I press a kiss to his cheek. "Maybe one day."
        *set Theron %+10
        Dragging yourself away from him is harder than it should be. 
    #I smile wistfully. "If only things were different."
        *set Theron %+5
        You retrieve your hand and drag yourself to your feet.
    #I snatch my hand away. "You're right, this is a waste of time."
        *set Theron %-10
        Hurt darts across his face as you get to your feet.

*label premain61

You can feel his mother watching you from her pallet next to the hearth. @{(awkwardkleia) You don't meet her eye. Instead you look up at the stars, readying to join them|You wave and she smiles, but it's tinged with sorrow, as though she's sad to see you go}.

@{(theronreason) You delivered your warning.|You delivered your warning.|You warned Theron even though you didn't have to or particularly care to.} The rest, is up to the Fates

"Goddess?" Theron calls as you're about to depart. He waits until you meet his gaze before he adds, "Thank you."

*label main61
*page_break Return Home

The next day, it's Zagreus who comes to fetch you from your chambers.

He's chosen a more muted outfit today. A purple chitoniskos–the kind he might wear on a hunt–and a crown of vines, with only the slightest hint of khol around his eyes. @{(Zagreus > 55) He greets you with a warm smile and a freshly plucked pomegranate, "Just because."|He greets you with a polite smile and your mother's instructions not to dilly-dally}.

"How goes the shadow teleporting?" you ask as he escorts you to the courtyard.

"Terribly," he sighs. "Averna seems more interested in berating me rather than teaching me."

"And that surprises you because?"

He lets out an exaggerated sigh. "Because she should be swept off her feet by my undeniable charm just like everyone else, of course."

"Of course."

Only your mother awaits by the horses this time. Far fewer flowers than usual adorn her simply-braided red hair, and she has chosen a stark, black gown that is more in line with your father's style. You haven't seen him since Argus escaped. Word is he hasn't left Tartarus, so intent he is on avoiding further destruction to the realm–and its reputation.

Perhaps her outfit choice is your mother's way of feeling like he's here somehow. Or perhaps it's to imprint into Zeus that, even though he isn't coming, their authority is one and the same.

"Right, children. Let us get this over and done with," she says, ushering you both into the chariot.

She
*if hermesoutcome < 3
    had been livid when you confessed what happened last night. @{(toldmama) At one point, you thought she might even chuck you into Tartarus|At one point, you thought she might even chuck you into Tartarus|First, that you kept Hermes's involvement from her, then that you failed so miserably at keeping him in check|At one point, you thought she might even chuck you into Tartarus}.

    You're under strict instructions not to talk in this meeting unless addressed by Zeus directly, and even then you are to say as little as possible.
    *goto main62
*elseif (hermesoutcome = 3) or (hermesoutcome > 5)
    *set hermesthere true
    had been impressed when you revealed @{(spiedonhermes) your findings|Hermes is bound by oath to hand himself in}. Even if @{(toldmama) coming by such an outcome might not have been exactly low profile|coming by such an outcome might not have been exactly low profile|she was livid you'd kept Hermes's involvement to yourself in the first place|coming by such an outcome might not have been exactly low profile}.
    *goto main62
*else
    has yet to throw you into Tartarus, and even brought you warm nectar when you got back from @{(didnotwarntheron) Hellas|Leukas}, which can only mean @{(morpheuswith) Morpheus kept his word|she isn't aware of your deceit}.
    *goto main62

*label main62

She picks up the reins and clicks her tongue. The horses pull you into the sky, obeying her like they would your father.

*page_break Journey To Olympus

@{(spiedonhermes) It's strange, to be back already|This time, there's no welcoming party awaiting you by the palace. Only a bustling army of nymphs and satyrs carrying supplies to a long line of carts stretching beyond the portico. Carts that will no doubt be hauled to Hellas for the feast}.

Hermes and Hera are surprised when the three of you are led to the throne room, where they had been sat on their respective thrones–Hera's positioned a few steps lower than Zeus's–drinking nectar in abject silence.

"Persephone," Zeus frowns. "We weren't expecting you quite so soon."

"I know, but I am afraid there is a matter of great urgency we must discuss before the feast planning committee is appointed."

Hera leans forward in her throne.
*if (injured = true) and (scar != 3)
    *set noticedscar1 true
    Then her gaze widens when she notices the scar etched into your @{(scar) shoulder|neck|na}.

    @{(noticedscar) And though her concern isn't as pronounced as Ares's had been, you glimpse the resemblance between mother and son, then. Hera's eyes and hair are darker, her skin a deep, richer bronze, but shock looks the same on both of them. Zeus|Zeus} follows her gaze and he, too, is immediately concerned.

    "${(name)}! Are you alright?" Hera wonders, then she looks to your mother. "Is all well?"
    *goto herazeuschat
*else
    "Is all well?"
    *goto herazeuschat

*label herazeuschat
*page_break

Your mother may be facing the two most powerful deities in Olympus while they're sat on their respective thrones, but she doesn't balk. She commandeers the attention with unflinching determination, and looks all the more regal because of it.

"I am afraid not. Argus was able to briefly breach @{(noticedscar1) Tartarus. Hence my daughter's injury|Tartarus}."

Careful as her words may be, they still draw outraged gasps from both Olympians.

"How could this happen?" Hera wonders at the same time as Zeus rages, "How could you let this happen?"

*choice
    #I rush to my mother's defence. How dare Zeus speak to her like that!
        @{(hermesoutcome < 3) Yes, she instructed you to keep your mouth shut. But the fact she had to in the first place proves how little you care for doing what you're told|Especially since it was his very son who [i]let[/i] this happen}.

        *if dutiful < 30
            *set underworldinfluence %+15
            *set pantheonplayer %-5
            *set parents %+5
            *set lockeduppoint true
            "Do not speak to my mother like that," you seethe. "The Underworld has kept the most dangerous beings in the cosmos locked up and away from mortals–and Olympians–for eons without incident. The benefit of the doubt is the least she deserves."

            The air around you grows static and, for a moment, you fear you might be struck down by a lightning bolt right here, right now.

            "I do not appreciate being told how to conduct myself in my own throne room," Zeus fumes. Then he drags one of his powerful hands down his beard and sighs. The air becomes breathable again, with only a hint of electricity tugging at your skin. "Though I suppose you are right. Persephone, you may continue."
            *goto main63
        *else
            *set olympusinfluence %-15
            *set pantheonplayer %-10
            @{(hermesoutcome < 3) So you'd like to believe, anyway. Alas,|But} one searing look from Zeus is all takes for the words to lodge in your throat.
            *goto main63      
    #I skewer Zeus with my most withering glare. He better settle down, or else.
        *if charm < 30
            *set olympusinfluence %+10
            *set parents %+10
            He does, nervously glancing between you and your mother and lifting his hands as though to apologize.

            "This is unsettling news. Please continue," he says in a much less accusatory tone.

            Good.
            *goto main63
        *else
            *set olympusinfluence %-10
            *set underworldinfluence %-15
            It immediately backfires.

            "Do you have something to say, nightmare weaver?" he sneers. 

            "She does not," you mother answers, glowering at you so intensely, you take a step back.

            "Good," Zeus seethes, and you can feel his rage in the suddenly staticky air.
            *goto main63
    #I appeal to Zeus's better judgement. Blaming my mother won't help.
        *set lockeduppoint true
        @{(hermesoutcome < 3) Yes, she instructed you to keep your mouth shut. But he wants you to marry his son. Surely that means he'll cut you some slack?|Especially since it's his own son who is responsible for this mess in the first place}.

        "I understand your frustrations. The Underworld has kept the most dangerous beings in the cosmos locked away for eons without incident. This is a troubling setback, yes, but one we can move past," you say, channeling your inner diplomat.

        *if diplomacy > 60
            *set pantheonplayer %+15
            *set olympusinfluence %+10
            It works. Zeus reclines back onto his throne with a sigh. "Fair point. My apologies, Persephone. Please proceed."
            *goto main63
        *else
            *set olympusinfluence %-15
            *set underworldinfluence %-15
            You don't know who's glare is more terrifying, Zeus's or your mother's. 

            "I will give you the same advice I give my war god son whenever he thinks to overstep. Know your place, or I will rip it from you."
            *goto main63
    #I let my mother defend herself. She knows what she's doing.
        *if leadership > 55
            *set parents %+10
            *set pantheonplayer %+10
            She's the Queen of the Underowrld, for Fates' sake.

            To intervene would only undermine her.
            *goto main63
        *else
            *set parents %-10
            *set pantheonplayer %-15
            But something about the way you carry yourself must alert her of your concern, because trails off mid sentence to shoot you a concerned glance.

            "Persephone?" Hera asks. "Do you need me to call for more nectar?"

            Your mother rises an eyebrow at you, but only when you nod does she answer the Olympian queen. "No, no. It's fine. Eh, where was I?"

            "Argus escaped," Zagreus offers. 

            "Ah yes, forgive me."
            *goto main63

*label main63
*page_break

"Believe me, nobody is more outraged by this breach than Hades and I," your mother presses on.
*if (hermesoutcome = 3)
    "That is why I must ask that you have Hermes brought here at once."

    Hera perks up at that. Zeus gives a sceptical smirk, but waves for a servant to do as she asks.
    *goto main64
*else
    "That is why we are investigating it thoroughly."
    *goto main64

*label main64
*page_break

*if hermesoutcome = 3 
    "I will entertain whatever business you have with my herald," Zeus allows. "But you had better start explaining what is going here."
    *goto premain65
*else
    "And what has your investigation concluded thus far?"
    *goto premain65

*label premain65

*if argusencounter = 3
    "We have determined Argus did not wish to flee the Underworld nor curry favor among the Giants," she offers. "Instead, he wished to die, drink from the Lethe, and become a soul."

    Hera stills, as though frozen to her throne by the news. Her expression turns cold and remote and, when she speaks, it is without feeling or inflexion. "Did he succeed?"

    "I am afraid so."

    A crack forms in the wall of ice that has become of the Olympian queen's face, but she says nothing in response. Perhaps because she has nothing to say, or perhaps because she can feel how keenly Zeus is watching her.

    "Pathetic. One of the fiercest warriors the realms have ever known, reduced to a tiny speck of light by his own hand. I suppose I ought to thank him for removing himself from our long list of worries so permanently. Not that he would recognize an old enemy in his diminished state," he smirks. Then, still watching Hera, he adds, "Or an old friend."

    He lets out a loud laugh before returning his attention to your mother. "While I am glad he is no longer a problem, this does not explain how he was able to escape the pit in the first place."
    *goto main65 
*else
    *goto main65

*label main65

*if hermesthere
    "We have concluded the only way Argus was able to leave the pit was with outside help," your mother offers.

    Zeus narrows his eyes at her. "So you have a traitor in your midst?"

    @{(spiedonhermes) "You called for me?" Hermes drawls, flitting into the throne room.|"Technically, you do," Hermes drawls. "For it was I who freed the Giant Argus."}
    *goto hermesishere
*else
    @{(argusdead) "We are working|"We have determined Argus has had no contact with the Giants since well before he was imprisoned. As for how he was able to escape the pit in the first place, we are still} working to determine that."

    Thunder roars in the distance. Static pricks your skin as Zeus brings down the full weight of his glare on your mother. "Is your intention to test my patience, Persephone? If so, you are succeeding greatly."

    @{(hermesoutcome < 3) Shame punches your gut. Not only did you fail, but you handed Hermes leverage against you–and your family–on a silver platter [i]and[/i] made them targets for Zeus's wrath. If the thunder god doesn't fry you, it won't be because you don't deserve it|You don't allow yourself to feel shame. Hermes isn't getting away with this. [i]You[/i] are. Zeus's anger is like a dark cloud; pervasive but fleeting}.
    *goto hermesnothere

*label hermesishere
*page_break 

*if spiedonhermes
    "Persephone did," Zeus tells him. "There has been an incident in Tartarus. Argus Panoptes was able to escape the pit, and the Underworld believes he had outside help."
    
    To his credit, he looks genuinely surprised. "Oh, that is rather troubling to hear. How may I be of assistance?"

    Your mother nods at you. Your cue to present your proof.

    "Well, for starters," you say, approaching Zeuns and Hera, but keeping your gaze on the herald. "You could tell us why you did it?"

    Silence descends upon the throne room.

    "No?" You summon the scrolls you took from the Archives, and the ones Morpheus handed over before you flew here, and passing them to Zeus and Hera. "Let me help with that. You have been tormenting patronless cities to worship you instead of other deities, and using us Messengers to encourage them to do it. If you would be so kind as to read those scrolls, you'll see the official ones do not match the ones Morpheus and I were given."

    "That is ridiculous," Hermes snorts, but he has gone pale beneath his hat, and his eyes dart between you and Zeus with a desperation that wasn't there before.

    "She is right," Zeus says, frowning at the scrolls. "I never gave you these instructions, but I do not understand what this has to do with Argus."

    "Well, you see, Morpheus discovered Hermes's little scheme, and confronted him about it. That didn't go so well, so Hermes here decided to retaliate in a pretty big way. Or rather, a prety giant way. Didn't you, Hermes?" Panic overtakes the herald's face, but you don't let him speak. Not yet. "@{(argusdead) Argus confirmed as much, before he died|If you mean to deny it, don't. It's only a matter of time before Argus's breaks and confirms as much}. He wasn't successful, you see. Morpheus is very much alive. @{(noticedscar1) Injured, more so than I was, but|Injured, but} alive."

    "Is it true, son?" Zeus asks, making Hera flinch. But he only has eyes for Hermes. "Could you really have disappointed me so?"
    *gosub_scene subroutines hermeszeus
    *goto punishmentchoice1
*else
    You've got to give it to the herald; he knows how to make an entrance.

    There is a lightness to the way he flits into the throne room, as though finally admitting to his scheme has relieved him of a great burden. 
        
    "What is this?" Zeus demands, looking at his son in horror. 

    "This is what happens when you push a god to his limits, [i]Father[/i]." 

    Hera flinches at the word. Perhaps his scheme isn't the only thing he's unburdening himself of today.
    *gosub_scene subroutines hermeszeus
    *goto punishmentchoice1

*label punishmentchoice1

@{(spiedonhermes) "Since it is you who uncovered my spineless son's treason and brought it to our attention, it is only right that it should be you who determines his punishment."|"[i]Forced his hand?[/i] So it is you I must thank for bringing my spineless son's act of treason to light?"}

*if (hermesoutcome > 5)
    *set hermespunished true
    *set hermespunishment 1
    This is it. The time to stick up for him.

    *fake_choice
        #"Treason is a strong word."
        #"I wouldn't call him spineless."
        #"He didn't need that much encouragement."
    
    Beside you, your mother tenses, and Zagreus smirks. "While it is true that Hermes acted poorly, it is also true that he has raised some concerns shared by many deities, including myself," you add.

    "${name}," your mother warns.
    
    Alas, @{(tricked) you want him to uphold his end of the bargain|a deal is a deal}, so you soldier on. "All I am saying is that the push for worship has taken its toll on everyone, and perhaps Hermes isn't exclusively to blame for resorting to such extreme measures to deliver it. Certainly, he shouldn't be thrown in Tartarus for it."

    "I see your point," Zeus concedes.
    *goto punishmentoutcome
*else
    *set hermespunished true
    You regard the herald carefully. How should he be punished?

    *fake_choice
        #"A stay in Tartarus should do it."
            *set hermespunishment 2
        #"He should step down from the Council."
            *set hermespunishment 3
        #"Let the Leukans decide. They've earned it."
            *set hermespunishment 4
            *set punishmentdecide 1
        #"Let Morhpeus decide. He's eaned it."
            *set hermespunishment 5
            *set punishmentdecide 2

    *goto punishmentoutcome

*label punishmentoutcome
*page_break

Hermes @{(hermespunishment) shoots you a grateful glance.|does something you have never seen a deity do before. He drops to his knees, and begs. "Please, you can't do this. You need me for the feast."|clenches his jaw, but doesn't say a word. Why would he? He's getting away lightly and he knows it.|stares at you in horror. To be punished by a mortal is almost more humiliating than Tartarus.|clenches his jaw. You can only imagine what Morpheus will do to him. Nothing good, that's for certain}.

Three lightning bolts strike the grass beyond the colonnade. They are followed by a cacophony of high-pitched, eagle-like cries.

Harpies.

"So be it," Zeus says as two wind spirits land between a pair of columns. If the columns weren't divine-made, you're certain they would've toppled them.

"You called for us, Lord Zeus?" one of them crows.

Both have lower bodies shaped like those of an eagle, with sharp faces and even sharper claws that scratch the tile, and the upper bodies of women.

*if hermespunishment = 2
    "Take my son to Tartarus, where he is to remain until the feast, when he will be given the opportunity to prove he has had enough time to learn the true meaning of loyalty," Zeus orders. "Oh, And tell Iris they have been appointed as interim Leader of the Messengers Council, we have important matters to attend to here."

    One of the harpies nods, the other shoots Hermes a predatory grin. Then they each take one of the herald's shoulders, and drag him out of the throne room while the rest of you watch on.

    "No! Father, please!" Hermes begs.

    It's a grim sight to witness. But, you suppose, necessary.
    *goto prezeusmeetingends
*else
    "Take my son to his chambers, where he shall remain confined until such a time I deem appropriate," Zeus tells them. "Oh, And tell Iris they have been appointed as interim Leader of the Messengers Council, we have important matters to attend to here."

    One of the harpies nods, while the other presses her long, sharp fingernails into Hermes's shoulder.
    
    "Is that really necessary, seeing as how I'm coming with you willingly?" he complains.
    
    "Hush, herald, or you'll soon learn what my real claws feel like," you hear one of the harpies snarl as they escort him out of the room.
    *goto prezeusmeetingends

*label prezeusmeetingends
*page_break

"We will not dwell on this," Zeus says, as though 
*if hermespunishment = 2
    he hasn't just witnessed his son be dragged to prison. "If we do, we risk losing the advantage we hope to gain by hosting a feast in the first place.""
    
    Hera clears her throat. "Quite right."
    *goto zeusmeetingends
*else
    he hasn't just discovered his son was stealing worship. "If we do, we risk losing the advantage we hope to gain by hosting a feast in the first place."

    Hera clears her throat. "Quite right."
    *goto zeusmeetingends

*label hermesnothere 
*page_break

"Zeus," Zagreus intervenes. "While this is troubling news, we cannot let it rattle us. Not unless we wish to risk losing the advantage we hope to gain by hosting a feast in the first place."

You don't know what surprises you more, his level-headedness, or the fact that it actually puts a dent in Zeus's rage. The thunder closing in on the palace lessens to a rumble, and the air around you becomes less charged.

"I am not rattled," Zeus huffs, but it's more cranky than furious.

"Of course not," Hera steps in, twisting around to face her husband. "But Zagreus has a @{(lockeduppoint) point, as did his sister. This|pount. Besides, this} is an anomaly. Tartarus has kept our fiercest of foes locked away without incident for eons. And though we must ensure a breakout never happens again, we can also trust the Underworld will deal with it with the same rigor and ruthlessness they have shown thus far."

Your mother tilts her chin at her. "Thank you."

"Fine," Zeus agrees, "but I expect to be informed of any development as soon as it occurs."

"You have my word."

*label zeusmeetingends

"Let us proceed, then," Zeus continues. "The committee will be in charge of organizing the feast and ensuring it runs smoothly. ${name}, weaver of nightmares, I have decided to grant you a reprieve from your duties so that you may act as its chief messenger. Zagreus, master of the hunt, I have appointed you to its defence contingent." He pauses, and a splinter of frustration works its way into his tone. "I was hoping my son Ares would join you, but he @{(aresishere) is otherwise indisposed|has yet to return from Poseidon's palace}, so you will be working alongside Athena."

@{(aresishere) You try not to feel guilty that visiting you might have worsened the tension between Ares and Zeus–and fail. Then Zagreus's|Zagreus's} gaze find yours. Neither of you have a choice in the matter and you both know it, but at least you're in it together.

"You honor my children, and I will personally ensure they take on these responsibilities with the dedication they deserve." A threat as much as an assurance.

*fake_choice
    #I bow.
        *set dutiful %+5
    #I smile.
        *set charm %+5
    #I nod.
        *set diplomacy %+5

The sound of footsteps behind you catches Zeus's attention. 

"Ah, right on time. You will all be working alongside Olympus's most industrious feast planner, of course," he says, gesturing for the newcomer to join you.

As you turn to face them, the cloying scent of wild roses hits your nostrils, and you know who you'll find by the throne room's entrance before you set eyes on her.

"Well, hello there, harpymeat," Aphrodite purrs. "Ready to party?"

Oh, Fates.

*choice
    #Continue to the next chapter.
        *finish Chapter 9
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint